Vui lòng giới thiệu một thư viện đa xử lý trong Perl hoặc Ruby

Question

Trong python, chúng tôi có thể sử dụng các mô-đun đa xử lý. Nếu có thư viện tương tự trong Perl và Ruby, bạn có dạy nó không? Tôi sẽ đánh giá cao nếu bạn có thể bao gồm một mẫu ngắn.

Answer 1

Với Perl, bạn có các tùy chọn. Một tùy chọn là sử dụng các quy trình như dưới đây. Tôi cần phải tìm cách viết chương trình tương tự bằng cách sử dụng các chủ đề nhưng http://perldoc.perl.org/perlthrtut.html sẽ cung cấp cho bạn một ý tưởng.

#!/usr/bin/perl 

use strict; 
use warnings; 

use Parallel::ForkManager; 

my @data = (0 .. 19); 

my $pm = Parallel::ForkManager->new(4); 

for my $n (@data) { 
    my $pid = $pm->start and next; 
    warn sprintf "%d^3 = %d\n", $n, slow_cube($n); 
    $pm->finish; 
} 

sub slow_cube { 
    my ($n) = @_; 

    sleep 1; 
    return $n * $n * $n; 
} 

__END__ 

Phiên bản sau đây sử dụng chủ đề không sử dụng một giới hạn về số lượng các chủ đề đã tạo (vì tôi không biết làm thế nào):

#!/usr/bin/perl 

use strict; 
use warnings; 

use threads; 

my @data = (0 .. 19); 
my @threads = map { 
    threads->new({context => 'list' }, \&slow_cube, $_) 
} @data; 

for my $thr (@threads) { 
    my ($n, $ncubed) = $thr->join; 
    print "$n^3 = $ncubed\n"; 
} 

sub slow_cube { 
    my ($n) = @_; 

    sleep 1; 
    return $n, $n * $n * $n; 
} 

__END__ 

Điều thú vị là:

TimeThis : Command Line : t.pl 
TimeThis : Elapsed Time : 00:00:01.281 

Answer 2

Ruby:

• Working with multiple processes in Ruby
• Concurrency is a Myth in Ruby

Perl:

• Harnessing the power of multicore
• Why Perl Is a Great Language for Concurrent Programming

Ngoài ra, chuỗi của Perl là chuỗi hệ điều hành gốc, vì vậy bạn có thể sử dụng chúng để tận dụng nhiều lõi.

Answer 3

Check-out Coro cung cấp coroutines cho Perl.

Dưới đây là một đoạn trích từ các tài liệu tác giả ....

bộ sưu tập mô-đun này quản lý continuations nói chung, thường xuyên nhất trong các hình thức của chủ đề hợp tác xã (còn gọi là coros, hoặc đơn giản là "Coro" trong tài liệu). Chúng tương tự như các luồng hạt nhân nhưng không (nói chung) chạy song song cùng một lúc ngay cả trên các máy SMP. Chủ đề cụ thể của thread được cung cấp bởi module này cũng đảm bảo rằng nó sẽ không chuyển đổi giữa các luồng trừ khi cần thiết, tại các điểm dễ xác định trong chương trình của bạn, vì vậy việc khóa và truy cập song song hiếm khi là vấn đề. các mô hình chủ đề khác.

Không giống như "chủ đề Perl" (không thực sự là chủ đề thực sự nhưng chỉ quy trình giả lập cửa sổ được chuyển sang Unix) và Coro cung cấp không gian địa chỉ dùng chung, chủ đề rất dễ dàng. Và các chủ đề của Coro cũng nhanh chóng: vô hiệu hóa mã mô phỏng quy trình Windows trong perl của bạn và sử dụng Coro có thể dễ dàng dẫn đến tăng gấp hai đến bốn lần tốc độ cho các chương trình của bạn. Một điểm chuẩn nhân ma trận song song chạy nhanh hơn 300 lần trên một lõi đơn so với các chuỗi giả của perl trên lõi tứ sử dụng tất cả bốn lõi.

Đối với một cái gì đó tương tự như trên trong Ruby sau đó có một cái nhìn tại Fiber mà đi kèm với Ruby 1.9.

Dưới đây là hai bài viết thú vị về việc sử dụng sợi quang:

• fibers cooperative scheduling in ruby
• pipelines using fibers

Ngoài ra còn có một Fiber for Perl sử dụng Coro. Dưới đây là một số bài viết về Fiber dành cho Perl (bằng tiếng Nhật):

• blog post on writing Fiber for Perl using Coro
• Fiber for Perl slides

Answer 4

Có một cái nhìn tại trang này tóm tắt tốt đẹp cho Perl libs xử lý song song http://www.openfusion.net/perl/parallel_processing_perl_modules. Tôi thích Parallel :: Forker, một thư viện hiện đại và mạnh mẽ hơn Parallel :: ForkManager cũ và có nhiều tính năng hơn như báo hiệu quá trình con. Tôi đã sử dụng nó trong nhiều dự án và nó hoạt động chính xác như mong đợi. Dưới đây là một ví dụ về cách sử dụng nó:

#!/usr/bin/env perl 

use strict; 
use warnings; 
use Parallel::Forker; 

my $forker = Parallel::Forker->new(use_sig_child => 1, max_proc => 4); 
$SIG{CHLD} = sub { 
    Parallel::Forker::sig_child($forker); 
}; 
$SIG{TERM} = sub { 
    $forker->kill_tree_all('TERM') if $forker and $forker->in_parent; 
    die "Exiting child process...\n"; 
}; 
# an example 
for (1..10) { 
    $forker->schedule(run_on_start => sub { 
     # all child process code to run here 
    })->ready(); 
} 
# wait for all child processes to finish 
$forker->wait_all(); 

Hy vọng điều này sẽ giúp bạn

Answer 5

https://github.com/pmahoney/process_shared cho ruby ​​