Disable tất cả các chỉ số không clustered

Question

tôi chọn một số chỉ số không clustered từ cơ sở dữ liệu của tôi với những điều sau đây:

SELECT sys.objects.name tableName, 
     sys.indexes.name indexName 
FROM sys.indexes 
     JOIN sys.objects ON sys.indexes.object_id = sys.objects.object_id 
WHERE sys.indexes.type_desc = 'NONCLUSTERED' 
     AND sys.objects.type_desc = 'USER_TABLE' 

Tôi muốn chạy sau hơn so với từng kết quả:

ALTER INDEX indexName ON tableName DISABLE 

Làm cách nào để tôi thực hiện việc này? Có cách nào tốt hơn?

EDIT

tôi đang làm điều này với mục đích cắt bỏ bảng, sau đó xây dựng lại với "ALTER INDEX bla ON bảng xây dựng lại". Điều này cần phải được tự động, do đó, giảm và xây dựng lại sẽ là một hoạt động bảo trì cao hơn một chút tôi muốn tránh. Đây có phải là kế hoạch tồi không? Tôi cần một phương tiện làm trống các bảng với chi phí tối thiểu.

Answer 1

Bạn có thể xây dựng các truy vấn vào một tuyên bố chọn, như vậy:

DECLARE @sql AS VARCHAR(MAX)=''; 

SELECT @sql = @sql + 
'ALTER INDEX ' + sys.indexes.name + ' ON ' + sys.objects.name + ' DISABLE;' +CHAR(13)+CHAR(10) 
FROM 
    sys.indexes 
JOIN 
    sys.objects 
    ON sys.indexes.object_id = sys.objects.object_id 
WHERE sys.indexes.type_desc = 'NONCLUSTERED' 
    AND sys.objects.type_desc = 'USER_TABLE'; 

EXEC(@sql); 

Chars 13 và 10 là những dòng thức ăn chăn nuôi/vận chuyển-lợi nhuận, vì vậy bạn có thể kiểm tra kết quả bằng cách thay thế EXEC với PRINT, và nó sẽ dễ đọc hơn.

Answer 2

Tạo biến bảng với các chỉ mục và tên bảng. Sử dụng một vòng lặp để lặp qua chúng, và thực thi một câu lệnh SQL động cho mỗi câu lệnh.

declare @Indexes table 
(
    Num  int identity(1,1) primary key clustered, 
    TableName nvarchar(255), 
    IndexName nvarchar(255) 
) 

INSERT INTO @Indexes 
(
    TableName, 
    IndexName 
) 
SELECT sys.objects.name tableName, 
     sys.indexes.name indexName 
FROM sys.indexes 
     JOIN sys.objects ON sys.indexes.object_id = sys.objects.object_id 
WHERE sys.indexes.type_desc = 'NONCLUSTERED' 
     AND sys.objects.type_desc = 'USER_TABLE' 

DECLARE @Max INT 
SET @Max = @@ROWCOUNT 

SELECT @Max as 'max' 
SELECT * FROM @Indexes 

DECLARE @I INT 
SET @I = 1 

DECLARE @TblName NVARCHAR(255), @IdxName NVARCHAR(255) 

DECLARE @SQL NVARCHAR(MAX) 

WHILE @I <= @Max 
BEGIN 
    SELECT @TblName = TableName, @IdxName = IndexName FROM @Indexes WHERE Num = @I 
    SELECT @SQL = N'ALTER INDEX ' + @IdxName + N' ON ' + @TblName + ' DISABLE;' 

    EXEC sp_sqlexec @SQL  

    SET @I = @I + 1 

END 

Answer 3

OTOH nó có thể là tốt hơn giảm khá DISABLE đó (hoặc là nó một lil nhỏ diff cú pháp giữa Oracle và MS SQL? :-) Lý do tôi đề cập đến là tôi nhớ bảng được repopulated và excplicilty denormalized hai lần một ngày và chúng tôi đã DROP-ing tất cả các chỉ mục để buộc DB để xây dựng lại cả hai chỉ số và kế hoạch thực hiện sproc sau khi chúng tôi nạp ngày mới và xây dựng lại tất cả các chỉ mục.

Tất nhiên chúng tôi đã có tập lệnh riêng biệt cho rằng kể từ khi bạn thả chúng, chỉ mục không có trong bảng hệ thống nữa.

Answer 4

Sử dụng con trỏ để tập lệnh có nhiều thành ngữ hơn bảng tạm thời (và hơi nhỏ). Để kích hoạt lại các chỉ mục, hãy thay thế DISABLE bằng REBUILD.

DECLARE cur_indexes CURSOR FOR 
SELECT sys.objects.name tableName, 
     sys.indexes.name indexName 
FROM sys.indexes 
     JOIN sys.objects ON sys.indexes.object_id = sys.objects.object_id 
WHERE sys.indexes.type_desc = 'NONCLUSTERED' 
     AND sys.objects.type_desc = 'USER_TABLE' 

DECLARE @TblName NVARCHAR(255), @IdxName NVARCHAR(255) 

DECLARE @SQL NVARCHAR(MAX) 

open cur_indexes 
fetch next from cur_indexes into @TblName, @IdxName 

WHILE @@FETCH_STATUS = 0 
BEGIN 
    SELECT @SQL = N'ALTER INDEX ' + @IdxName + N' ON ' + @TblName + ' DISABLE;' 

    EXEC sp_sqlexec @SQL  

    fetch next from cur_indexes into @TblName, @IdxName 
END 

close cur_indexes 
deallocate cur_indexes