Vòng lặp phụ thuộc đối tượng Oracle

Question

Tôi gặp sự cố, khi tôi cố gắng biên dịch dự án của mình trong Cơ sở dữ liệu Oracle. Để làm cho nó đơn giản hơn, tôi có ba đối tượng: 2 gói (UTILS và TYPES) ​​và 1 view (VIEW).

Gói UTILS đang sử dụng các loại được xác định trong TYPES gói. TYPES gói đang sử dụng VIEW làm cơ sở cho một trong các loại đó. Và VIEW đang sử dụng các hàm từ gói UTILS trong tập lệnh của nó. Khi tôi cố gắng thực hiện một số thay đổi đối với một trong các đối tượng này, tôi không thể biên dịch được vì mọi thứ đều ở trạng thái không hợp lệ. Vì vậy, một số loại phụ thuộc đối tượng vòng lặp được tạo ra.

Vui lòng giúp tôi giải quyết vấn đề này.

Ví dụ: có cách nào để biên dịch mã bên dưới không? Mỗi đối tượng là một cú pháp chính xác, nhưng làm thế nào tất cả chúng có thể được biên dịch cùng nhau?

create or replace package my_types is 
    type type1 is table of number; 
    type type2 is table of my_view%rowtype; 
end; 
/

create or replace package my_utils is 
    function get_1 return number; 
    procedure do_something(parameter my_types.type2); 
end; 
/

create or replace package body my_utils is 
    function get_1 return number is 
    begin 
     return 1; 
    end; 

    procedure do_something(parameter my_types.type2) is 
    begin 
     null; 
    end; 
end; 
/

create or replace force view my_view as 
select * from dual 
where 1 = my_utils.get_1(); 

exec dbms_utility.compile_schema(user, false); 

select object_name from user_objects where status <> 'VALID'; 

Answer 1

Nếu bạn không muốn/không thể phân chia gói hoặc chế độ xem của mình, bạn luôn có thể tạo phiên bản giả của chế độ xem trước, biên dịch các gói và tạo chế độ xem "thực" sau:

create or replace package my_types is 
    type type1 is table of number; 
    type type2 is table of my_view%rowtype; 
end; 
/

create or replace package my_utils is 
    function get_1 return number; 
    procedure do_something(parameter my_types.type2); 
end; 
/

create or replace package body my_utils is 
    function get_1 return number is 
    begin 
     return 1; 
    end; 

    procedure do_something(parameter my_types.type2) is 
    begin 
     null; 
    end; 
end; 
/

create or replace force view my_view as 
select * from dual; 

exec dbms_utility.compile_schema(user, false); 

create or replace force view my_view as 
select * from dual 
where 1 = my_utils.get_1(); 

select object_name from user_objects where status <> 'VALID'; 

Answer 2

Nếu bạn phá vỡ quan điểm trong hai quan điểm, bạn có thể phá vỡ sự phụ thuộc theo chu kỳ:

create or replace view my_view_1 
as select * from dual; 

create or replace package my_types is 
    type type1 is table of number; 
    type type2 is table of my_view_1%rowtype; 
end; 
/

create or replace package my_utils is 
    function get_1 return number; 
    procedure do_something(parameter my_types.type2); 
end; 
/

create or replace package body my_utils is 
    function get_1 return number is 
    begin 
     return 1; 
    end; 

    procedure do_something(parameter my_types.type2) is 
    begin 
     null; 
    end; 
end; 
/

create or replace view my_view as 
select * from my_view_1 
where 1 = my_utils.get_1(); 

EDIT: Một khả năng khác là để phá vỡ my_utils gói trong hai:

create or replace package my_utils_1 is 
    function get_1 return number; 
end; 
/
create or replace package body my_utils_1 is 
    function get_1 return number is 
    begin 
     return 1; 
    end; 
end; 
/

create or replace view my_view as 
select * from dual 
where 1 = my_utils_1.get_1(); 

create or replace package my_types is 
    type type1 is table of number; 
    type type2 is table of my_view%rowtype; 
end; 
/

create or replace package my_utils_2 is 
    procedure do_something(parameter my_types.type2); 
end; 
/
create or replace package body my_utils_2 is 
    procedure do_something(parameter my_types.type2) is 
    begin 
     null; 
    end; 
end; 
/

Answer 3

Tôi không sử dụng các loại đóng gói và% ROWTYPE. Đây không phải là SQL tiêu chuẩn và có thể được thay thế bằng Structured Types

create or replace view my_view_1 
as select * from dual; 

create or replace type type1 as table of number; 
create or replace type type2 as object (DUMMY VARCHAR2(1 byte)); 
create or replace type table_type2 as table of type2; 

create or replace package my_utils is 
    function get_1 return number; 
    procedure do_something(parameter table_type2); 
end; 
/

create or replace package body my_utils is 
    function get_1 return number is 
    begin 
     return 1; 
    end; 

    procedure do_something(parameter table_type2) is 
    begin 
     null; 
    end; 
end; 
/

create or replace view my_view as 
select * from my_view_1 
where 1 = my_utils.get_1();