Nhận URL hiện tại trong IE Sử dụng Visual Basic

Question

Tôi đang làm việc với đối tượng Internet Explorer trong Visual Basic. Có cách nào để sao chép URL hiện tại mà IE đang hiển thị để tôi có thể dán nó ở nơi khác bằng khay nhớ tạm của tôi không?

Answer 1

Giả sử bạn đã có cửa sổ IE xác định, mà tự nó là một chút phức tạp hơn - tôi có thể xây dựng trên này nếu cần thiết:

Dim ieIEWindow As SHDocVw.InternetExplorer 
Dim sIEURL As String 

'Set your IE Window 

sIEURL = ieIEWindow.LocationURL 

Để có được cửa sổ IE, bạn sẽ cần phải tham khảo thư viện Microsoft Internet Controls (ieframe.dll) trong trình chỉnh sửa VBA bằng cách truy cập Tools =>References... và chọn từ danh sách. Nếu mục đó không có sẵn, tệp .dll cho tôi nằm ở C:\Windows\System32\ieframe.dll.

Khi tham chiếu được đặt, bạn sẽ có quyền truy cập vào thư viện được gọi là SHDocVw trong mã của bạn.

Bạn có thể lấy các cửa sổ IE (giả sử chỉ có một mở) bằng cách sử dụng sau đây (chưa được kiểm tra, điều chỉnh/giảm từ mã làm việc của riêng tôi):

Public Function GrabIEWindow() As SHDocView.InternetExplorer 

Dim swShellWindows As New SHDocVw.ShellWindows 
Dim ieOpenIEWindow As SHDocVw.InternetExplorer 

    Set GrabIEWindow = Nothing 

    ' Look at the URLs of any active Explorer windows 
    ' (this includes WINDOWS windows, not just IE) 
    For Each ieOpenIEWindow In objShellWindows 

     ' Check the I.E. window to see if it's pointed 
     ' to a web location (http) 
     If Left$(ieOpenIEWindow.LocationURL, 4) = "http" Then 
      ' If so, set this window as the one to use. 
      ' This will need to be modified to create 
      ' a list if you want to select from more 
      ' than one open window 

      ' Optional grab the HWND for later reference... 
      Dim lWindowID As Long 
      lWindowID = ieOpenIEWindow.HWND 

      Set GrabIEWindow = ieOpenIEWindow 

      Exit Function 
     End If 

    Next OpenIEWindow 

End Function 

Trên đây cũng có thể được sửa đổi để cho phép một sự lựa chọn của nhiều cửa sổ IE đang mở.

Answer 2

Chết tiệt! Điều này nhắc tôi về vb6 ngày của tôi :)

Ok đây là những gì tôi có. Nếu có nhiều hơn 1 cửa sổ IE thì cửa sổ IE sẽ hoạt động lần cuối (hiện tại) nếu chỉ có một cửa sổ thì sẽ mất.

'~~> Set a reference to Microsoft Internet Controls 

'~~> The GetWindow function retrieves the handle of a window that has 
'~~> the specified relationship (Z order or owner) to the specified window. 
Private Declare Function GetWindow Lib "user32" (ByVal hwnd As Long, _ 
ByVal wCmd As Long) As Long 

'~~> The GetForegroundWindow function returns the handle of the foreground 
'~~> window (the window with which the user is currently working). 
Private Declare Function GetForegroundWindow Lib "user32"() As Long 

Sub GetURL() 
    Dim sw As SHDocVw.ShellWindows 
    Dim objIE As SHDocVw.InternetExplorer 
    Dim topHwnd As Long, nextHwnd As Long 
    Dim sURL As String, hwnds As String 

    Set sw = New SHDocVw.ShellWindows 

    '~~> Check the number of IE Windows Opened 
    '~~> If more than 1 
    hwnds = "|" 
    If sw.Count > 1 Then 
     '~~> Create a string of hwnds of all IE windows 
     For Each objIE In sw 
      hwnds = hwnds & objIE.hwnd & "|" 
     Next 

     '~~> Get handle of handle of the foreground window 
     nextHwnd = GetForegroundWindow 

     '~~> Check for the 1st IE window after foreground window 
     Do While nextHwnd > 0 
      nextHwnd = GetWindow(nextHwnd, 2&) 
      If InStr(hwnds, "|" & nextHwnd & "|") > 0 Then 
       topHwnd = nextHwnd 
       Exit Do 
      End If 
     Loop 

     '~~> Get the URL from the relevant IE window 
     For Each objIE In sw 
      If objIE.hwnd = topHwnd Then 
       sURL = objIE.LocationURL 
       Exit For 
      End If 
     Next 
    '~~> If only 1 was found 
    Else 
     For Each objIE In sw 
      sURL = objIE.LocationURL 
     Next 
    End If 

    Debug.Print sURL 

    Set sw = Nothing: Set objIE = Nothing 
End Sub 

LƯU Ý: Tôi đã không thực hiện bất kỳ xử lý lỗi. Tôi chắc chắn bạn có thể chăm sóc điều đó;)