Gnuplot: Logscale dường như làm mọi thứ lộn xộn lên

Question

Tôi đặt một xlogscale vào và nó làm sai lệch bản vẽ của các đường lưới. Các đường lưới x chính không còn có màu xám giống như các đường lưới y chính, chúng có màu xám của các đường lưới x và y nhỏ.

Sau đây để hình ảnh hiển thị thông tin này.

Bất kỳ ý tưởng nào về cách khắc phục sự cố này?

Cảm ơn

#!/usr/bin/env gnuplot 

set term pdfcairo size 15cm,10cm 
set output 'FFT.pdf' 

set datafile separator ' ' 
unset key 

set border lw 4 back 

set grid mxtics mytics xtics ytics lt 1 lc rgb 'gray70', lt 1 lc rgb 'gray90' 

set mxtics 5 
set mytics 5 

set xrange [10:10e3] 

set title 'Harmonic Distortion' 
set xlabel 'Frequency [Hz]' 
set ylabel 'Output Voltage [dB]' 

set mxtics 10 
set logscale x 10 

plot 'FFT.dat' using ($1):(20*log10((($2**2)+($3**2))**0.5)-5.49074) with lines lw 4 lc rgb 'red' 

set out 

Answer 1

Bạn có thể giải quyết điều này bằng cách chỉ set mxtics sử dụng, mà không chỉ định bất kỳ tần số:

set term pdfcairo size 15cm,10cm 
set output 'FFT.pdf' 

unset key 
set samples 1000 
set border lw 4 back 

set grid xtics ytics mxtics mytics lc rgb 'blue' lt 1, lc rgb 'red' lt 1 

set xrange [10:10000] 
set mxtics 
set mytics 5 
set logscale x 10 

plot sin(0.001*x) with lines lw 4 lc rgb 'green70' 

set out 

tôi đã sử dụng màu sắc phân biệt tốt hơn cho gr dòng id. Kết quả với 4.6.3 là:

Tôi không biết, tại sao điều này xảy ra. Theo tài liệu hướng dẫn set mxtics 10 nên được sử dụng tốt. Tôi sẽ báo cáo lỗi này.