Sử dụng giá trị của một biến trong chế độ áp dụng-mẫu

Question

Tôi muốn áp dụng mẫu có chế độ phụ thuộc vào giá trị biến.

<xsl:variable name="mode" select="@attribute"/> 
<xsl:apply-templates mode="{$mode}"/> 

Tôi gặp lỗi khi không thể biên soạn biểu định kiểu. Giá trị của chế độ phải là một QName, nhưng nó là "{$ mode}".

Có khả năng sử dụng các chế độ phụ thuộc vào biến không?

Answer 1

Các lựa chọn duy nhất bạn phải sử dụng một chế độ nhất định dựa trên một biểu thức là sử dụng

<xsl:choose> 
    <xsl:when test="@attribute = 'foo'"> 
     <xsl:apply-templates mode="bar"/> 
    </xsl:when> 
    <xsl:otherwise> 
     <xsl:apply-templates/> 
    </xsl:otherwise> 
</xsl:choose> 

hoặc tương tự với một xsl:if. Giá trị thuộc tính mode thuộc tính cần phải tương ứng là QName trong XSLT 1.0 trong XSLT 2.0 cho phép QName hoặc mã thông báo đặc biệt như #current hoặc #default '. Nhưng bạn không thể tính toán giá trị mode vào thời gian chạy.

Answer 2

chế độ không phải là ứng cử viên hợp lệ cho Mẫu giá trị thuộc tính (AVT). Bạn chỉ đơn giản là không thể làm điều này.

Từ XSLT 2.0 spec:

[Định nghĩa: Trong một thuộc tính được chỉ định là một giá trị thuộc tính mẫu, chẳng hạn như một thuộc tính của một yếu tố kết quả theo nghĩa đen, một biểu có thể được sử dụng bởi xung quanh khái niệm với các dấu ngoặc nhọn ({})].

chế độ không được chỉ định là AVT trong thông số kỹ thuật, vì vậy bạn không thể thực hiện điều này.

Answer 3

Tôi gặp lỗi khi không thể biên soạn biểu định kiểu. Giá trị của chế độ phải là QName, nhưng đó là "{$ mode}".

Có khả năng sử dụng các chế độ phụ thuộc vào biến không?

Không, điều này không được hỗ trợ trong bất kỳ phiên bản XSLT nào - 1.0, 2.0 hoặc 3.0.

Khi bạn đang cố gắng thi đua hàm bậc cao hơn (HOF), bạn có thể sử dụng nguyên tắc cơ bản của FXSL để thực hiện điều này trong XSLT 1.0.

FXSL 1.x là thư viện các mẫu được viết bằng XSLT 1.0 thuần túy hỗ trợ/mô phỏng HOF.

Đây là một giải pháp hoàn chỉnh dựa trên những nguyên tắc:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
xmlns:f="http://fxsl.sf.net" exclude-result-prefixes="f"> 
<xsl:output omit-xml-declaration="yes" indent="yes"/> 
<xsl:strip-space elements="*"/> 

    <f:inc/> 
    <f:double/> 

<xsl:variable name="vModeInc" select="document('')/*/f:inc[1]"/> 
<xsl:variable name="vModeDouble" select="document('')/*/f:double[1]"/> 

<xsl:template match="node()|@*"> 
    <xsl:copy> 
     <xsl:apply-templates select="node()|@*"/> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match="/*"> 
    <nums> 
    <xsl:apply-templates select="$vModeInc"> 
     <xsl:with-param name="pNodes" select="node()"/> 
    </xsl:apply-templates> 
    </nums> 
============== 
    <nums> 
    <xsl:apply-templates select="$vModeDouble"> 
     <xsl:with-param name="pNodes" select="node()"/> 
    </xsl:apply-templates> 
    </nums> 
</xsl:template> 

<xsl:template match="f:inc"> 
    <xsl:param name="pNodes"/> 
    <xsl:apply-templates select="$pNodes" mode="incr"/> 
</xsl:template> 

<xsl:template match="f:double"> 
    <xsl:param name="pNodes"/> 
    <xsl:apply-templates select="$pNodes" mode="double"/> 
</xsl:template> 

<xsl:template match="num" mode="incr"> 
    <num><xsl:value-of select=".+1"/></num> 
</xsl:template> 

<xsl:template match="num" mode="double"> 
    <num><xsl:value-of select=".*2"/></num> 
</xsl:template> 
</xsl:stylesheet> 

Khi chuyển đổi này được áp dụng trên các tài liệu XML sau:

<nums> 
    <num>01</num> 
    <num>02</num> 
    <num>03</num> 
    <num>04</num> 
    <num>05</num> 
    <num>06</num> 
    <num>07</num> 
    <num>08</num> 
    <num>09</num> 
    <num>10</num> 
</nums> 

các truy nã, kết quả đúng là được sản xuất - các phần tử nums/num được xử lý trong một (mỗi) của hai chế độ có sẵn, de cấp phát trên biến quy định - $vModeInc (1 thêm vào mỗi giá trị) hoặc $vModeDouble (mỗi giá trị được nhân hai):

<nums> 
    <num>2</num> 
    <num>3</num> 
    <num>4</num> 
    <num>5</num> 
    <num>6</num> 
    <num>7</num> 
    <num>8</num> 
    <num>9</num> 
    <num>10</num> 
    <num>11</num> 
</nums> 
============== 
    <nums> 
    <num>2</num> 
    <num>4</num> 
    <num>6</num> 
    <num>8</num> 
    <num>10</num> 
    <num>12</num> 
    <num>14</num> 
    <num>16</num> 
    <num>18</num> 
    <num>20</num> 
</nums>