Hợp nhất danh sách bản đồ và kết hợp các giá trị với các bộ trong Clojure

Question

Tôi có thể đặt chức năng nào làm FOO ở đây để mang lại giá trị đúng vào cuối? Tôi đã chơi với bộ băm (chỉ đúng cho 2 giá trị đầu tiên), conj, và concat nhưng tôi biết tôi không xử lý đơn nguyên tố vs set condition đúng với bất kỳ điều nào trong số đó.

(defn mergeMatches [propertyMapList] 
    "Take a list of maps and merges them combining values into a set" 
    (reduce #(merge-with FOO %1 %2) {} propertyMapList)) 

(def in 
    (list 
     {:a 1} 
     {:a 2} 
     {:a 3} 
     {:b 4} 
     {:b 5} 
     {:b 6})) 

(def out 
    { :a #{ 1 2 3} 
     :b #{ 4 5 6} }) 

; this should return true 
(= (mergeMatches in) out) 

Cách thành ngữ nhất để xử lý vấn đề này là gì?

Answer 1

này sẽ thực hiện:

(let [set #(if (set? %) % #{%})] 
    #(clojure.set/union (set %) (set %2))) 

Viết lại trực tiếp hơn cho các ví dụ (Alex):

(defn to-set [s] 
    (if (set? s) s #{s})) 
(defn set-union [s1 s2] 
    (clojure.set/union (to-set s1) (to-set s2))) 
(defn mergeMatches [propertyMapList] 
    (reduce #(merge-with set-union %1 %2) {} propertyMapList)) 

Answer 2

tôi sẽ không sử dụng kết hợp với các cho điều này,

(defn fnil [f not-found] 
    (fn [x y] (f (if (nil? x) not-found x) y))) 
(defn conj-in [m map-entry] 
    (update-in m [(key map-entry)] (fnil conj #{}) (val map-entry))) 
(defn merge-matches [property-map-list] 
    (reduce conj-in {} (apply concat property-map-list))) 

user=> (merge-matches in) 
{:b #{4 5 6}, :a #{1 2 3}} 

fnil sẽ là một phần của lõi sớm để bạn có thể bỏ qua việc thực hiện ... nhưng nó chỉ tạo ra một phiên bản của một hàm khác có thể xử lý nil arg uments. Trong trường hợp này conj sẽ thay thế # {} cho nil.

Vì vậy, việc giảm liên kết với tập hợp cho mỗi khóa/giá trị trong danh sách các bản đồ được cung cấp.

Answer 3

Không siêu đẹp nhưng nó hoạt động.

(defn mergeMatches [propertyMapList] 
    (for [k (set (for [pp propertyMapList] (key (first pp))))] 
     {k (set (remove nil? (for [pp propertyMapList] (k pp))))})) 

Answer 4

Điều này dường như làm việc:

(defn FOO [v1 v2] 
     (if (set? v1) 
      (apply hash-set v2 v1) 
      (hash-set v1 v2))) 

Answer 5

tôi không viết những dòng này nhưng nó đã contributed bởi @amitrathore trên Twitter:

(defn kv [bag [k v]] 
    (update-in bag [k] conj v)) 
(defn mergeMatches [propertyMapList] 
    (reduce #(reduce kv %1 %2) {} propertyMapList)) 

Answer 6

Một giải pháp góp của @wmacgyver trên Twitter dựa trên multimaps:

(defn add 
    "Adds key-value pairs the multimap." 
    ([mm k v] 
    (assoc mm k (conj (get mm k #{}) v))) 
    ([mm k v & kvs] 
    (apply add (add mm k v) kvs))) 
(defn mm-merge 
    "Merges the multimaps, taking the union of values." 
    [& mms] 
    (apply (partial merge-with union) mms)) 

(defn mergeMatches [property-map-list] 
    (reduce mm-merge (map #(add {} (key (first %)) (val (first %))) property-map-list)))