Nhiều SPARQL "INSERT WHERE" truy vấn trong một yêu cầu duy nhất

Question

Câu hỏi của tôi cũng tương tự như những gì đã được hỏi về chủ đề này Is it possible to combine those 2 SPARQL INSERT into one?

Tôi muốn có nhiều INSERT ĐÂU báo cáo trong một truy vấn, nhưng đối với các đối tượng khác nhau. Tôi muốn thử nghiệm một giá trị cụ thể ("testValueN") và nếu hiện tại muốn chèn một giá trị mới cho đối tượng đó.

Một ví dụ về nó sẽ là,

PREFIX Sensor: <http://example.com/Equipment.owl#> 
{ 
    INSERT { 
     ?subject1 Sensor:test2 'newValue1' . 
      } 
    WHERE { 
     ?subject1 Sensor:test1 'testValue1' . 
      } 
}; 
{ 
    INSERT { 
     ?subject2 Sensor:test2 'newValue2' . 
      } 
    WHERE { 
     ?subject2 Sensor:test1 'testValue2' . 
      } 
}; 

Tôi biết các truy vấn trên là sai. Tôi muốn biết nếu một cái gì đó tương tự là có thể trong SPARQL.

Answer 1

Có, điều này là có thể. Thực tế, ví dụ của bạn gần như hoàn toàn tốt đẹp, chỉ cần mất các dấu ngoặc xung quanh mỗi lần chèn:

PREFIX Sensor: <http://example.com/Equipment.owl#> 
INSERT { 
    ?subject1 Sensor:test2 'newValue1' . 
} 
WHERE { 
    ?subject1 Sensor:test1 'testValue1' . 
}; 
INSERT { 
    ?subject2 Sensor:test2 'newValue2' . 
} 
WHERE { 
    ?subject2 Sensor:test1 'testValue2' . 
} 

là một chuỗi cập nhật SPARQL hợp lệ.

Answer 2

Tôi muốn có nhiều câu lệnh INSERT WHERE trong truy vấn, nhưng cho các chủ đề khác nhau. Tôi sẽ thử nghiệm một giá trị cụ thể ("testValueN") và nếu hiện tại muốn chèn một giá trị mới cho đối tượng đó.

Bạn có thể làm điều này bằng giá trị để xác định các cặp OldValue/newValue mà bạn muốn, và nó chỉ đòi hỏi một đơn chèn. Nó cũng quy mô độc đáo hơn cho các cặp mới, vì bạn chỉ phải thêm một dòng vào truy vấn.

PREFIX Sensor: <http://example.com/Equipment.owl#> 
INSERT { 
    ?subject Sensor:test2 ?newValue 
} 
WHERE { 
    values (?oldValue ?newValue) { 
     ('testValue1' 'newValue1') 
     ('testValue2' 'newValue2') 
    } 
    ?subject Sensor:test1 ?oldValue 
}