nhắc nhập mật khẩu trong Haskell dòng lệnh ứng dụng

Question

sau Chương trình Haskell nhắc nhở người dùng cho một mật khẩu trong nhà ga và tiếp tục nếu anh ta đã bước vào đúng một:

main = do 
    putStrLn "Password:" 
    password <- getLine 

    case hash password `member` database of 
     False -> putStrLn "Unauthorized use!" 
     True -> do 
       ... 

Thật không may, mật khẩu sẽ xuất hiện trên màn hình khi người dùng gõ nó, mà tôi muốn tránh.

Làm cách nào để đọc chuỗi ký tự mà người dùng nhập mà không hiển thị trên màn hình? Tương đương với getLine cho mục đích này là gì?

Tôi đang sử dụng MacOS X, nhưng tôi cũng muốn điều này cũng hoạt động trên Windows và Linux.

Answer 1

Hãy thử tiếp theo:

module Main 
where 

import System.IO 
import Control.Exception 

main :: IO() 
main = getPassword >>= putStrLn . ("Entered: " ++) 

getPassword :: IO String 
getPassword = do 
    putStr "Password: " 
    hFlush stdout 
    pass <- withEcho False getLine 
    putChar '\n' 
    return pass 

withEcho :: Bool -> IO a -> IO a 
withEcho echo action = do 
    old <- hGetEcho stdin 
    bracket_ (hSetEcho stdin echo) (hSetEcho stdin old) action 

Answer 2

Có thể vô hiệu hóa lặp lại trong thiết bị đầu cuối với the System.Posix.Terminal module. Tuy nhiên, điều này đòi hỏi hỗ trợ POSIX, vì vậy có thể không hoạt động trên Windows (tôi đã không kiểm tra).

import System.Posix.Terminal 
import System.Posix.IO (stdInput) 

getPassword :: IO String 
getPassword = do 
    tc <- getTerminalAttributes stdInput 
    setTerminalAttributes stdInput (withoutMode tc EnableEcho) Immediately 
    password <- getLine 
    setTerminalAttributes stdInput tc Immediately 
    return password 

main = do 
    putStrLn "Password:" 
    password <- getPassword 
    putStrLn "Name:" 
    name <- getLine 
    putStrLn $ "Your password is " ++ password ++ " and your name is " ++ name 

Lưu ý rằng stdin là dòng đệm, vì vậy nếu bạn sử dụng putStr "Password:" thay vì putStrLn, bạn cần phải tuôn ra bộ đệm đầu tiên, nếu không kịp thời sẽ bị ức chế cũng có.

Answer 3

Có một getPassword trong System.Console.Haskeline. Có lẽ nó là một overkill cho trường hợp của bạn nhưng ai đó có thể tìm thấy nó hữu ích.

Một ví dụ:

> runInputT defaultSettings $ do {p <- getPassword (Just '*') "pass:"; outputStrLn $ fromJust p} 
pass:*** 
asd 

Answer 4

Như tôi đã nhận xét ở trên, tôi đề nghị bạn sử dụng haskeline, mà là một thư viện kịp thời đầy đủ. Tôi đã sử dụng nó một cách vui vẻ cho LambdaCalculator mà không có khiếu nại.

Answer 5

withEcho có thể được viết với một chút ít noice:

withEcho :: Bool -> IO a -> IO a 
withEcho echo action = 
    bracket (hGetEcho stdin) 
      (hSetEcho stdin) 
      (const $ hSetEcho stdin echo >> action)