CoffeeScript Lớp viên

Question

Tôi mới vào CoffeeScript (và khá thiếu kinh nghiệm với JS quá, vì thế xin lỗi nếu điều này là ngây thơ) và tôi đã cố gắng để tạo ra một lớp như sau:

class Test 
    a: [] 

    make: -> 
     @a.push ['A', 'B', 'C'] 

    getdata: -> 
     output = "" 
     for i in @a 
      output += i 
     output 

b = new Test 
b.make() 

alert(b.getdata()) 


c = new Test 
c.make() 

alert(c.getdata()) 

Kết quả tôi nhận được là: "A, B, C" "A, B, C, A, B, C"

Mặc dù tạo một trường hợp mới của 'Kiểm tra'; mảng được nối thêm và không bị xóa. Tôi làm gì sai ở đây? Tôi có khởi tạo biến thành viên sai không?

Answer 1

Khi bạn xác định a: [], bạn đang tạo một đối tượng mảng đơn trên nguyên mẫu lớp. Mỗi cá thể của lớp mà bạn tạo sẽ có cùng một đối tượng mảng này. Bất cứ khi nào một cá thể thay đổi giá trị, thay đổi sẽ hiển thị cho tất cả các giá trị khác.

Lưu ý rằng đây chỉ là trường hợp nếu bạn sửa đổi một giá trị, chẳng hạn như bằng cách thêm các mục vào một mảng. Nếu bạn thay thế giá trị, ví dụ bằng cách gán một mảng mới, điều này sẽ chỉ ảnh hưởng đến cá thể hiện tại.

Khi bạn muốn có một tài sản đó là khởi tạo trên cơ sở mỗi thẩm bạn nên xác định nó trong constructor, khi dụ được thực sự tạo:

class Test 
    constructor: -> 
     @a = [] 
     @a.push ['A', 'B', 'C'] 

    getdata: -> 
     output = "" 
     for i in @a 
      output += i 
     output 

b = new Test 

alert(b.getdata()) 


c = new Test 

alert(c.getdata()) 

Try this out và bạn sẽ thấy rằng nó hoạt động như bạn muốn.