SAS - Làm cách nào để nhận các quan sát 'n' cuối cùng từ tập dữ liệu?

Question

Làm cách nào bạn có thể tạo tập dữ liệu SAS từ tập dữ liệu khác chỉ sử dụng các quan sát n cuối cùng từ tập dữ liệu gốc. Điều này rất dễ dàng khi bạn biết giá trị của n. Nếu tôi không biết 'n' làm thế nào điều này có thể được thực hiện?

Answer 1

Giả sử bạn có biến macro cho biết có bao nhiêu quan sát bạn muốn. NOBS cho bạn biết số quan sát trong tập dữ liệu hiện tại mà không cần đọc toàn bộ.

%let obswant=5; 
data want; 
set sashelp.class nobs=obscount; 
if _n_ gt (obscount-&obswant.); 
run; 

Answer 2

Sử dụng ví dụ của một biến vĩ mô của Joe để xác định số lượng các quan sát mà bạn muốn, đây là một câu trả lời:

%let obswant = 10; 
data want; 
    do _i_=nobs-(&obswant-1) to nobs; 
     set have point=_i_ nobs=nobs; 
     output; 
     end; 
    stop; /* Needed to stop data step */ 
run; 

này nên thực hiện tốt hơn vì nó chỉ đọc quan sát cụ thể mà bạn muốn.

Answer 3

Vì lợi ích của đa dạng, đây là cách tiếp cận khác (không nhất thiết là một tốt hơn)

%let obswant=5; 

proc sql noprint; 
select nlobs-&obswant.+1 into :obscalc 
from dictionary.tables 
where libname='SASHELP' and upcase(memname)='CLASS'; 
quit; 

data want; 
set sashelp.class (firstobs=&obscalc.); 
run; 

Answer 4

Nếu dữ liệu quá lớn, bạn có thể không muốn đọc toàn bộ tập dữ liệu. Thay vào đó, bạn có thể thử một công trình đọc tổng số Quan sát trong tập dữ liệu trước tiên. Vì vậy, nếu bạn muốn có những quan sát cuối cùng:

data t; 
    input x; 
datalines; 
1 
2 
3 
4 
; 

%let dsid=%sysfunc(open(t)); 
%let num=%sysfunc(attrn(&dsid,nlobs)); 
%let rc=%sysfunc(close(&dsid)); 
%let number = 2; 

data tt; 
set t (firstobs = %eval(&num.-&number.+1)); 
run;