Tính năng __LINE__ trong Groovy

Question

Có thể lấy số dòng hiện tại bằng __LINE__ trong Ruby hoặc Perl. Ví dụ:

print "filename: #{__FILE__}, line: #{__LINE__}" 

Có tính năng tương tự trong Groovy không?

Answer 1

Không trực tiếp, nhưng bạn có thể lấy thông qua dấu vết ngăn xếp Ngoại lệ (hoặc Có thể bỏ qua). Ví dụ:

StackTraceElement getStackFrame(String debugMethodName) { 
    def ignorePackages = [ 
     'sun.', 
     'java.lang', 
     'org.codehaus', 
     'groovy.lang' 
    ] 
    StackTraceElement frame = null 
    Throwable t = new Throwable() 
    t.stackTrace.eachWithIndex { StackTraceElement stElement, int index -> 
     if (stElement.methodName.contains(debugMethodName)) { 
      int callerIndex = index + 1 
      while (t.stackTrace[callerIndex].isNativeMethod() || 
        ignorePackages.any { String packageName -> 
         t.stackTrace[callerIndex].className.startsWith(packageName) 
        }) { 
       callerIndex++ 
      } 
      frame = t.stackTrace[callerIndex] 
      return 
     } 
    } 
    frame 
} 

int getLineNumber() { 
    getStackFrame('getLineNumber')?.lineNumber ?: -1 
} 

String getFileName() { 
    getStackFrame('getFileName')?.fileName 
} 

String getMethodName() { 
    getStackFrame('getMethodName')?.methodName 
} 

def foo() { 
    println "looking at $fileName:$lineNumber ($methodName)" 
} 

foo() 

// ==> looking at test.groovy:39 (foo) 

Một lời cảnh báo mặc dù: nhận được số dòng, tên file, hoặc phương pháp như thế này là rất chậm.

Answer 2

Tôi không phải là chuyên gia trong Groovy, nhưng tôi không nghĩ vậy. Tôi biết rằng Java và C# không có nó.

Tính năng __LINE__ thực sự bắt đầu giúp gỡ lỗi trong C. C không có ngoại lệ hoặc nhiều tính năng khác hiện có ngôn ngữ, nhưng nó có macro mà trình biên dịch có thể mở rộng ở bất kỳ đâu trong mã, đó là lý do chúng tôi cần __FILE__, __LINE__, v.v. để cho chúng tôi biết chúng tôi đã ở đâu khi có điều gì đó xấu xảy ra. Đây là cách assert hoạt động trong C và C++. JVM có các công cụ gỡ lỗi rất tốt và kết hợp với assert và các ngoại lệ, bạn có thể dễ dàng xác định nơi đã xảy ra sự cố (ngăn xếp dấu vết tốt hơn chỉ là số dòng).

Tôi tin rằng lý do Ruby và Perl có các macro đó là do chúng được tạo bởi tin tặc C. Tôi chưa bao giờ sử dụng một trong hai ngôn ngữ đó đủ để biết mức độ hỗ trợ gỡ lỗi hoặc các macro thực sự hữu ích như thế nào.