Có cách nào để làm cho SAS dừng lại khi cảnh báo hoặc lỗi đầu tiên không?

Question

SAS thích tiếp tục xử lý tốt sau khi cảnh báo và lỗi, vì vậy tôi thường cần phải cuộn lại qua các trang trong nhật ký để tìm sự cố. Có cách nào tốt hơn? Tôi muốn nó dừng lại ngay khi lỗi hoặc cảnh báo đầu tiên xuất hiện để tôi có thể sửa lỗi và thử lại.

Answer 1

Tùy chọn ERRORS = 1 đã được đề xuất trước đó, nhưng điều đó chỉ dừng lại các thông báo L ERI từ ghi vào nhật ký. Tôi sẽ đề nghị một lựa chọn hệ thống khác ERRORABEND mà sẽ ngăn chặn chương trình xử lý tiếp tục cho hầu hết các lỗi. Tôi không biết một tùy chọn để chấm dứt xử lý do cảnh báo, nhưng tôi nghĩ rằng bạn có thể thêm macro như sau để ngừng xử lý.

%macro check_for_errors; 
    %if &syserr > 0 %then %do; 
     endsas; 
    %end; 
%mend check_for_errors; 

data test1; 
    <data step code> 
run; 
%check_for_errors; 

Bạn có thể lặp lại các cuộc gọi vĩ mô sau mỗi bước của chương trình của bạn, và nó sẽ chấm dứt tại thời điểm đó mã lỗi là bất cứ điều gì nhưng 0.

Answer 2

tôi thường xuyên làm điều gì đó tương tự như RWill, nhưng tôi bọc toàn bộ chương trình của tôi trong một macro. Sau mỗi bước DATA, PROC SQL, PROC SORT, v.v. Tôi kiểm tra mã lỗi (& SYSERR hoặc & SQLRC). Nếu nó không khác, tôi nhảy đến cùng.

Thông tin chi tiết và mã ở đây: https://heuristically.wordpress.com/2012/02/09/return-codes-errors-sas/

tôi không thể sử dụng endsas vì cách hệ thống hàng loạt tổ chức của chúng tôi chạy chương trình độc lập trong một phiên SAS RWill của.

Answer 3

Một tùy chọn là thay thế run bằng run &g_cancel trong suốt và proc sql; với proc sql &g_noexec;. Ban đầu &g_cancel và &g_noexec được đặt thành không có gì để mọi thứ đều chạy.

Khi gặp lỗi (hoặc %sys_rc, %sql_rc hoặc sử dụng đề cập đến logic nghiệp vụ), hãy đặt &g_cancel để hủy và &g_noexec thành noexec.

Điều này sẽ dừng mọi bước tiếp theo khi chạy - rõ ràng là các biến macro có thể được bỏ qua cho các bước phải chạy bất kể (ví dụ: dọn dẹp) hoặc kiểm tra trước khi thực hiện các bước hoàn toàn bằng macro.

Lưu ý đối với người dùng Hướng dẫn doanh nghiệp: Lưu ý cảnh báo duy nhất là nếu bạn đang chạy nhiều mục mã trong cùng một phiên, bạn sẽ cần phải đặt lại các điều khoản lỗi ở đầu mỗi mục mã, vì sợ rằng các lỗi không liên quan sẽ ngừng hoạt động.

Answer 4

Gần đây tôi đã sử dụng macro %runquit. Hoạt động tốt cho cả công việc theo lô và các phiên tương tác (không đóng phiên của bạn, chỉ dừng chạy mã).

Nguồn: http://www.cpc.unc.edu/research/tools/data_analysis/sas_to_stata/sas-macros/runquit.html

Để sử dụng nó về cơ bản bạn gõ %runquit; ở phần cuối của bất cứ bước nào dữ liệu hoặc PROC thay vì gõ đều đặn run hoặc quit tuyên bố của bạn.

Code:

%macro runquit; 
    ; run; quit; 
    %if &syserr. ne 0 %then %do; 
    %abort cancel; 
    %end; 
%mend runquit; 

sử dụng Datastep:

data something; 
* do some stuff; 
%runquit; 

sử dụng PROC:

proc sql; 
    * do some stuff; 
%runquit; 

Nó không phải là khá đẹp khi đọc qua mã, nhưng nó làm cho gỡ lỗi rất nhiều dễ dàng hơn.

Answer 5

Như bổ sung cho Rwill của câu trả lời:

Nếu bạn đang sử dụng một quá trình lưu trữ (STP), nó cũng tốt đẹp để không hiển thị nhật ký cho người dùng khi một lỗi xảy ra và để loại bỏ các "Show SAS log" nút .

Đó có thể đạt được với nguồn

%macro checkcc; 
    options obs=max no$syntaxcheck; 
    %if (&syscc gt 4) %then 
     %do; 
      data _null_; 
       file _webout; 
       put "<h3>Sorry, your request was not processed successfully.<h3>"; 
       rc = stpsrvset('program error', 0); 
      run; 
     %end; 
    %let syscc=0; 
%mend checkcc; 
%checkcc; 

này: http://support.sas.com/kb/16/225.html

Và đây là một phiên bản nâng cao mà tôi thực hiện để vẫn hiển thị các lỗi trong định dạng json.

%macro checkErrors; 
    options obs=max no$syntaxcheck; 
    %let old = %sysfunc(stpsrv_header(Content-type, application/json%str(;) charset=utf-8)); 
    %put &=syscc; %put &=syserr; %put &=sysrc; %put &=syswarningtext; %put &=syserrortext; 
    %if (&syscc gt 4) %then %do; 
     data _null_; 
      file _webout; 
      put '{'; 
      put ' "success":"false"'; 
      put ' ,"message":"' "&syserrortext" '"'; 
      put ' ,"syscc":"' "&syscc" '"'; 
      put '}'; 
      rc = stpsrvset('program error', 0); 
      run; 
     %end; 
    %let syscc=0; 
%mend checkErrors; 
%checkErrors; 

và HTML phiên bản:

%macro checkErrors_HTML; 
    options obs=max no$syntaxcheck; 
    %if (&syscc gt 4) %then %do; 
     data _null_; 
      file _webout; 
      put '<!doctype html> '; 
      put '<html> '; 
      put ' <head> '; 
      put '  <title>Error</title> '; 
      put ' </head> '; 
      put ' <body> '; 
      put '  <h1>An Error Occured</h1>'; 
      put '  <p>' "&syserrortext" '</>'; 
      put ' </body>'; 
      put '</html>'; 
      rc = stpsrvset('program error', 0); 
      run; 
     %end; 
    %let syscc=0; 
%mend checkErrors_HTML; 
%checkErrors_HTML;