đếm số lượng các cuộc gọi của một khoản

Question

Tôi có một điều khoản như sau:

lock_open:- 
     conditional_combination(X), 
     equal(X,[8,6,5,3,6,9]),!, 
     print(X). 

khoản này thành công. Nhưng tôi muốn biết bao nhiêu lần conditional_combination() được gọi trước khi equal(X,[8,6,5,3,6,9]) trở thành sự thật. chương trình là tạo ra một hoán vị bằng cách làm theo một số quy tắc. Và tôi cần phải có bao nhiêu hoán vị là cần phải tạo ra để có được một giá trị cụ thể như 865369.

Answer 1

Điều bạn thực sự muốn có gì đó hơi khác: Bạn muốn đếm số câu trả lời (cho đến nay) của một mục tiêu.

Vị từ sau call_nth(Goal_0, Nth) thành công như call(Goal_0) nhưng có một đối số bổ sung cho biết câu trả lời được tìm thấy là câu trả lời thứ n. Định nghĩa này rất cụ thể đối với SWI hoặc YAP. Làm không phải sử dụng những thứ như nb_setarg/3 trong các chương trình chung của bạn, nhưng sử dụng chúng cho các trường hợp được gói gọn như trường hợp này. Ngay cả trong phạm vi hai hệ thống này, ý nghĩa chính xác của các cấu trúc này không được xác định rõ ràng cho trường hợp chung. Here is a definition for SICStus.

 
call_nth(Goal_0, C) :- 
    State = count(0,_), % note the extra argument which remains a variable 
    Goal_0, 
    arg(1, State, C1), 
    C2 is C1+1, 
    nb_setarg(1, State, C2), 
    C = C2. 

Một trừu tượng mạnh mẽ hơn được cung cấp bởi Eclipse:

call_nth(Goal_0, Nth) :- 
    shelf_create(counter(0), CounterRef), 
    call(Goal_0), 
    shelf_inc(CounterRef, 1), 
    shelf_get(CounterRef, 1, Nth). 

 
?- call_nth(between(1,5,I),Nth). 
I = Nth, Nth = 1 ; 
I = Nth, Nth = 2 ; 
I = Nth, Nth = 3 ; 
I = Nth, Nth = 4 ; 
I = Nth, Nth = 5. 

Vì vậy, chỉ đơn giản là quấn nó xung quanh:

 
lock_open :- 
    call_nth(conditional_combination(X), Nth), 
    X = [8,6,5,3,6,9], 
    !, 
    .... 

Answer 2

Nếu bạn đang sử dụng SWI Prolog bạn có thể sử dụng nb_getval/2 và nb_setval/2 để đạt được những gì bạn muốn:

lock_open:- 
    nb_setval(ctr, 0), % Initialize counter 
    conditional_combination(X), 
    nb_inc(ctr), % Increment Counter 
    equal(X,[8,6,5,3,6,9]), 
    % Here you can access counter value with nb_getval(ctr, Value) 
    !, 
    print(X). 

nb_inc(Key):- 
    nb_getval(Key, Old), 
    succ(Old, New), 
    nb_setval(Key, New). 

prologs khác có các phương tiện khác để làm tương tự, hãy tìm các biến toàn cầu trong việc thực hiện prolog của bạn. Trong đoạn này tôi đã sử dụng thuật ngữ ctr để giữ bộ đếm mục tiêu hiện tại. Bạn có thể sử dụng bất kỳ thuật ngữ nào không được sử dụng trong chương trình của bạn.