Tìm tất cả các tài liệu tham khảo sử dụng trong công thức Excel

Question

Dưới đây là ví dụ thiết lập trong Excel,

[column1] [column2] 

A1 =C3-C5 

A2 =((C4-C6)/C6) 

A3 =C4*C3 

A4 =C6/C7 

A5 =C6*C4*C3 

tôi cần phải trích xuất các tài liệu tham khảo sử dụng trong công thức

Ví dụ,

for "A1", I simply need to get the C3 and C5. 
for A2, I need to get the C4 and C6. 

Answer 1

Chức năng này trả lại cho bạn danh sách các ô nguồn được phân cách bằng dấu phẩy (tiền lệ):

 
Function References(rngSource As Range) As Variant 
    Dim rngRef As Range 
    Dim strTemp As String 
    On Error Resume Next 
    For Each rngRef In rngSource.Precedents.Cells 
     strTemp = strTemp & ", " & rngRef.Address(False, False) 
    Next 
    If Len(strTemp) 0 Then strTemp = Mid(strTemp, 3) 
    References = strTemp 
End Function 

Tuy nhiên, xin lưu ý rằng bạn không thể sử dụng điều này làm UDF trong trang tính, vì không may là rngRef.Address gây ra tham chiếu vòng tròn. Tuy nhiên, bạn có thể sử dụng nó trong một quy trình nhỏ để điền một cột khác, ví dụ:

 
Sub ShowPrecedents() 
    Dim rng As Range 
    'Will paste precedents of A1:A6 into D1:D6 
    For Each rng In Range("D1:D6") 
     rng.Value = References(rng.Offset(, -3)) 
    Next 
End Sub 

Answer 2

Chỉ cần cung cấp cho bạn một sự thay thế ... Lưu ý rằng đây sẽ trả về kết quả trùng lặp nếu các tế bào được gọi là nhiều hơn một lần

Sub testing() 
Dim result As Object 
Dim r As Range 
Dim testExpression As String 
Dim objRegEx As Object 

Set r = Cells(1, 2) ' INPUT THE CELL HERE , e.g. cells("A1") 
Set objRegEx = CreateObject("VBScript.RegExp") 
objRegEx.IgnoreCase = True 
objRegEx.Global = True 
objRegEx.Pattern = """.*""" ' remove expressions 
testExpression = CStr(r.Formula) 
testExpression = objRegEx.Replace(testExpression, "") 
objRegEx.Pattern = "(([A-Z])+(\d)+)" 'grab the address 

If objRegEx.test(testExpression) Then 
    Set result = objRegEx.Execute(testExpression) 
    If result.Count > 0 Then 
     For Each Match In result 
      Debug.Print Match.Value 
     Next Match 
    End If 
End If 
End Sub 

Kết quả được lưu trữ trong "Match.Value"

Answer 3

Đây là bản cập nhật cho:

Sẽ hoạt động đối với tham chiếu trang tính cục bộ chứ không phải cho tài liệu tham khảo ngoài trang tính. - brettdj 14 Tháng 5 '14 lúc 11:55

Bởi Sử dụng phương pháp Larrys, chỉ cần thay đổi objRegEx.Pattern tới:

(['].*?['!])?([[A-Z0-9_]+[!])?(\$?[A-Z]+\$?(\d)+(:\$?[A-Z]+\$?(\d)+)?|\$?[A-Z]+:\$?[A-Z]+|(\$?[A-Z]+\$?(\d)+)) 

này sẽ:

1. Tìm kiếm Liên kết ngoài tùy chọn : (['].*?['!])?
2. Tìm kiếm tham chiếu Bảng tùy chọn: ([[A-Z0-9_]+[!])?
3. Làm như sau ps để ưu tiên:
4. Tìm kiếm dãy với số lượng hàng (Và tùy chọn $): \$?[A-Z]+\$?(\d)+(:\$?[A-Z]+\$?(\d)+)?
5. Tìm kiếm dãy chưa có số hàng (Và tùy chọn $): \$?[A-Z]+:\$?[A-Z]+
6. Tìm kiếm tài liệu tham khảo 1 cell (Và tùy chọn $): (\$?[A-Z]+\$?(\d)+)

Hệ quả này:

Sub testing() 
Dim result As Object 
Dim r As Range 
Dim testExpression As String 
Dim objRegEx As Object 

Set r = Cells(1, 2) ' INPUT THE CELL HERE , e.g. RANGE("A1") 
Set objRegEx = CreateObject("VBScript.RegExp") 
objRegEx.IgnoreCase = True 
objRegEx.Global = True 
objRegEx.Pattern = """.*?""" ' remove expressions 
testExpression = CStr(r.Formula) 
testExpression = objRegEx.Replace(testExpression, "") 
objRegEx.Pattern = "(([A-Z])+(\d)+)" 'grab the address 

objRegEx.Pattern = "(['].*?['!])?([[A-Z0-9_]+[!])?(\$?[A-Z]+\$?(\d)+(:\$?[A-Z]+\$?(\d)+)?|\$?[A-Z]+:\$?[A-Z]+|(\$?[A-Z]+\$?(\d)+))" 
If objRegEx.test(testExpression) Then 
    Set result = objRegEx.Execute(testExpression) 
    If result.Count > 0 Then 
     For Each Match In result 
      Debug.Print Match.Value 
     Next Match 
    End If 
End If 
End Sub 

việc làm này, sẽ cung cấp cho bạn các giá trị của tất cả các tài liệu tham khảo càng tốt, tôi có thể nghĩ của. (Cập nhật bài đăng này, bởi vì tôi cần giải quyết vấn đề).