Có cách nào để hiển thị thời gian xây dựng của toàn bộ giải pháp trong Visual Studio không?

Question

Tôi biết có a way to display the build time of each project contained in a solution in visual studio. Nhưng những gì tôi đang tìm kiếm là tổng thời gian cần thiết để xây dựng một giải pháp hoàn chỉnh, từ thời điểm tôi nhấp vào xây dựng, đến thời điểm nó được thực hiện.

Có cách nào để thực hiện việc này không? Chạy Visual Studio 2008.

Answer 1

EDIT: Đây là một cách bạn có thể viết thời gian xây dựng trực tiếp đến việc xây dựng cửa sổ.

Mở IDE Visual Studio Macro.
Điều hướng đến MyMacros> EnvironmentEvents.
Trong MyMacros, hãy thêm tham chiếu đến System.Windows.Forms (cho mã bên dưới để hiển thị cửa sổ bật lên).
Thêm mã này vào module EnvironmentEvents:

Dim buildStart As Date 

Private Function IsBuild(ByVal scope As EnvDTE.vsBuildScope, ByVal action As EnvDTE.vsBuildAction) As Boolean 
    Return scope = vsBuildScope.vsBuildScopeSolution AndAlso (action = vsBuildAction.vsBuildActionBuild OrElse action = vsBuildAction.vsBuildActionRebuildAll) 
End Function 

Private Sub BuildEvents_OnBuildBegin(ByVal Scope As EnvDTE.vsBuildScope, ByVal Action As EnvDTE.vsBuildAction) Handles BuildEvents.OnBuildBegin 
    If (IsBuild(Scope, Action)) Then 
     buildStart = Date.Now 
    End If 
End Sub 

Private Sub BuildEvents_OnBuildDone(ByVal Scope As EnvDTE.vsBuildScope, ByVal Action As EnvDTE.vsBuildAction) Handles BuildEvents.OnBuildDone 
    If (IsBuild(Scope, Action)) Then 
     Dim buildTime = Date.Now - buildStart 
     WriteToBuildWindow(String.Format("Build time: {0}", buildTime.ToString)) 
    End If 
End Sub 

Private Sub WriteToBuildWindow(ByVal message As String) 
    Dim win As Window = DTE.Windows.Item(EnvDTE.Constants.vsWindowKindOutput) 
    Dim ow As OutputWindow = CType(win.Object, OutputWindow) 
    For Each owPane As OutputWindowPane In ow.OutputWindowPanes 
     If (owPane.Name.Equals("Build")) Then 
      owPane.OutputString(message) 
      Exit For 
     End If 
    Next 
End Sub 

Khi bạn xây dựng hoặc xây dựng lại các giải pháp đầy đủ, ở cuối, xây dựng/xây dựng lại thời gian sẽ được in vào cửa sổ xây dựng đầu ra. Bạn có thể thay đổi các điều kiện trong IsBuild cho phù hợp với sở thích của bạn.

Answer 2

Tools-> Options-> Dự án và Giải pháp> VC++ Dự án Settings-> Xây dựng Thời gian