Trong XSLT làm cách nào để tăng biến toàn cầu từ một phạm vi khác?

Question

Tôi đang xử lý tệp XML nơi tôi muốn giữ số lượng nút, để tôi có thể sử dụng nó làm ID khi tôi viết các nút mới.

Hiện tại tôi có một biến toàn cầu có tên là 'bộ đếm'. Tôi có thể truy cập nó trong một khuôn mẫu, nhưng tôi đã không tìm thấy một cách để thao tác nó trong một khuôn mẫu.

Đây là một phiên bản đặc của tập tin XSLT tôi:

<xsl:variable name="counter" select="1" as="xs:integer"/> 

<xsl:template match="/"> 
    <xsl:for-each select="section"> 
     <xsl:call-template name="section"></xsl:call-template> 
    </xsl:for-each> 
</xsl:template> 

<xsl:template name="section"> 

    <!-- Increment 'counter' here --> 

    <span class="title" id="title-{$counter}"><xsl:value-of select="title"/></span> 
</xsl:template> 

Mọi góp ý thế nào để đi từ đây?

Answer 1

Những người khác đã giải thích như thế nào biến là không thay đổi - rằng không có câu lệnh gán trong XSLT (như với ngôn ngữ lập trình hoàn toàn chức năng nói chung).

Tôi có một giải pháp thay thế cho các giải pháp đã được đề xuất cho đến thời điểm này. Nó tránh đi qua tham số (nó dài dòng và xấu xí trong XSLT - thậm chí tôi sẽ thừa nhận điều đó).

Trong XPath, bạn chỉ có thể đếm số <section> yếu tố mà trước hiện thời:

<xsl:template name="section"> 
    <span class="title" id="title-{1 + count(preceding-sibling::section)}"> 
    <xsl:value-of select="title"/> 
    </span> 
</xsl:template> 

(Lưu ý: mã định dạng khoảng trắng sẽ không xuất hiện trong kết quả của bạn, như khoảng trắng chỉ các nút văn bản Vì vậy, đừng cảm thấy bị ép buộc phải đặt các chỉ dẫn trên cùng một dòng.)

Một lợi thế lớn của phương pháp này (trái ngược với việc sử dụng position()) là nó chỉ phụ thuộc vào nút hiện tại, chứ không phải trên danh sách nút hiện tại. Nếu bạn đã thay đổi cách xử lý của mình bằng cách nào đó (ví dụ: do đó, <xsl:for-each> không chỉ xử lý các phần mà còn một số phần tử khác), thì giá trị của position() sẽ không còn tương ứng với vị trí của các yếu tố <section> trong tài liệu của bạn. Mặt khác, nếu bạn sử dụng count() như trên, thì nó sẽ luôn tương ứng với vị trí của mỗi phần tử <section>. Cách tiếp cận này làm giảm sự ghép nối với các phần khác của mã của bạn, mà nói chung là một điều rất tốt.

Cách thay thế để đếm() sẽ là sử dụng hướng dẫn <xsl:number>. Đó là hành vi mặc định sẽ đánh số tất cả các yếu tố như tên cùng cấp, mà sẽ xảy ra là những gì bạn muốn:

<xsl:template name="section"> 
    <xsl:variable name="count"> 
    <xsl:number/> 
    </xsl:variable> 
    <span class="title" id="title-{$count}"> 
    <xsl:value-of select="title"/> 
    </span> 
</xsl:template> 

Đó là một sự đánh đổi trong tính cách rườm rà (đòi hỏi một khai báo biến bổ sung nếu bạn vẫn muốn sử dụng giá trị thuộc tính của các mẫu dấu ngoặc nhọn), nhưng chỉ một chút, vì nó cũng đơn giản hóa đáng kể biểu thức XPath của bạn.

Vẫn còn nhiều chỗ để cải thiện. Mặc dù chúng tôi đã xóa phụ thuộc vào danh sách nút hiện tại nhưng chúng tôi vẫn phụ thuộc vào nút hiện tại. Điều đó, trong và của chính nó, không phải là một điều xấu, nhưng nó không phải ngay lập tức rõ ràng từ nhìn vào mẫu những gì các nút hiện tại là. Tất cả những gì chúng ta biết là mẫu được đặt tên là "section"; để biết chắc chắn những gì đang được xử lý, chúng ta phải tìm nơi khác trong mã của chúng tôi. Nhưng ngay cả điều đó không phải là trường hợp.

Nếu bạn cảm thấy đã dẫn đến sử dụng <xsl:for-each> và <xsl:call-template> cùng nhau (như trong ví dụ của bạn), hãy quay lại và tìm hiểu cách sử dụng <xsl:apply-templates> thay thế.

<xsl:template match="/doc"> 
    <xsl:apply-templates select="section"/> 
</xsl:template> 

<xsl:template match="section"> 
    <xsl:variable name="count"> 
    <xsl:number/> 
    </xsl:variable> 
    <span class="title" id="title-{$count}"> 
    <xsl:value-of select="title"/> 
    </span> 
</xsl:template> 

Không chỉ là phương pháp này ít tiết (<xsl:apply-templates/> thay thế cả hai <xsl:for-each> và <xsl:call-template/>), nhưng nó cũng trở nên ngay lập tức rõ ràng những gì nút hiện tại là. Tất cả những gì bạn phải làm là nhìn vào thuộc tính match và bạn ngay lập tức biết rằng bạn đang xử lý một phần tử <section> và các thành phần <section> là những gì bạn đang đếm.

Để có giải thích ngắn gọn về cách các quy tắc mẫu (tức là <xsl:template> các phần tử có thuộc tính match) hoạt động, hãy xem "How XSLT Works".

Answer 2

biến được định vị cục bộ và chỉ đọc trong xslt.

Answer 3

Biến XSLT không thể thay đổi. Bạn sẽ chuyển giá trị từ mẫu này sang mẫu khác.

Nếu bạn đang sử dụng XSLT 2.0, bạn có thể có tham số và sử dụng đường hầm để truyền biến cho đúng mẫu.

Mẫu của bạn sẽ trông giống như thế này:

<xsl:template match="a"> 
<xsl:param name="count" select="0"> 
    <xsl:apply-templates> 
    <xsl:with-param select="$count+1"/> 
    </xsl:apply-templates> 
</xsl:template> 

Ngoài ra nhìn vào sử dụng generate-id() nếu bạn muốn tạo id.

Answer 4

Chưa tự mình thử, nhưng bạn có thể thử và chuyển một tham số cho mẫu. Trong mẫu đầu tiên của bạn, bạn đặt tham số để đếm() (hoặc current() có thể?) Trong câu lệnh for-each và sau đó chuyển giá trị đó cho mẫu "section" của bạn.

Dưới đây là thêm về passing parameters to templates

Answer 5

Tùy thuộc vào bộ xử lý XSLT của bạn, bạn có thể giới thiệu chức năng kịch bản vào XLST của bạn. Ví dụ, thư viện Microsoft XML hỗ trợ việc đưa javascript vào. Xem http://msdn.microsoft.com/en-us/library/aa970889(VS.85).aspx để biết ví dụ. Chiến thuật này rõ ràng sẽ không hoạt động nếu bạn dự định triển khai/thực hiện XSLT trên các trình duyệt khách hàng công cộng; nó phải được thực hiện bởi một bộ xử lý XSLT cụ thể.

Answer 6

Bạn có thể sử dụng hàm position() để thực hiện những gì bạn muốn. Nó sẽ trông như thế này

<xsl:template match="/"> 
    <xsl:for-each select="section"> 
    <xsl:call-template name="section"> 
     <xsl:with-param name="counter" select="{position()}"/> 
    </xsl:call-template> 
    </xsl:for-each> 
</xsl:template> 

<xsl:template name="section"> 
    <xsl:param name="counter"/> 
    <span class="title" id="title-{$counter}"> 
    <xsl:value-of select="title"/> 
    </span> 
</xsl:template> 

Answer 7

Các biến trong XSLT là không thay đổi, do đó bạn phải phê duyệt vấn đề đó. Bạn có thể có thể sử dụng trực tiếp position():

<xsl:template match="/"> 
    <xsl:for-each select="section"> 
     <xsl:call-template name="section"/> 
    </xsl:for-each> 
</xsl:template> 

<xsl:template name="section"> 
    <span class="title" id="title-{position()}"><xsl:value-of select="title"/></span> 
</xsl:template> 

Hoặc trong một khuôn mẫu định hướng nhiều cách:

<xsl:template match="/"> 
    <xsl:apply-templates select="section"/> 
</xsl:template> 

<xsl:template match="section"> 
    <span class="title" id="title-{position()}"><xsl:value-of select="title"/></span> 
</xsl:template> 

Answer 8

Sử dụng <xsl:variable name="RowNum" select="count(./preceding-sibling::*)" /> và $ ROWNUM như một giá trị incrementing.

Ví dụ: <xsl:template name="ME-homeTiles" match="Row[@Style='ME-homeTiles']" mode="itemstyle"> <xsl:variable name="RowNum" select="count(./preceding-sibling::*)" /> ...<a href="{$SafeLinkUrl}" class="tile{$RowNum}"><img ....></a>

này sẽ tạo ra các lớp học cho liên kết với các giá trị tile1, tile2, tile3 vv ...