Kiểm tra xem kết nối ADODB có đang mở không

Question

Tôi sử dụng các thao tác sau từ trong một số quy trình excel để thiết lập kết nối với cơ sở dữ liệu của chúng tôi.

Private Const strConn As String = _ 
    "PROVIDER=SQLOLEDB.1 ..."  

Sub OpenConnection() 

Set cn = CreateObject("ADODB.Connection") 
cn.Open strConn 
cn.CommandTimeout = 0 
Set rs = CreateObject("ADODB.Recordset") 
Set rs.ActiveConnection = cn 

End Sub 

Trong mã tiếp theo, tôi mở kết nối bằng nhiều chuỗi SQL khác nhau.
Tôi muốn thử nghiệm nếu rs mở để tôi biết rằng nó cần phải đóng nhưng những điều sau không hoạt động. Làm thế nào tôi có thể thay đổi điều kiện trong những điều sau đây để làm việc?

If (rs.Open = True) Then 
    rs.Close 
End If 

Các công trình sau đây nhưng tôi không muốn sử dụng lỗi bẫy theo cách này:

On Error Resume Next 
    rs.Close 

Answer 1

ADO Recordset có .State thuộc tính, bạn có thể kiểm tra xem giá trị của nó là adStateClosed hoặc adStateOpen

If Not (rs Is Nothing) Then 
    If (rs.State And adStateOpen) = adStateOpen Then rs.Close 
    Set rs = Nothing 
End If 

MSDN about State property

Chỉnh sửa; Lý do không kiểm tra .State với 1 hoặc 0 là bởi vì ngay cả khi nó hoạt động 99,99% thời gian, vẫn có thể có other flags set điều này sẽ làm cho câu lệnh If thất bại trong việc kiểm tra adStateOpen.

Chỉnh sửa2:

Đối với ràng buộc trễ mà không có đối tượng dữ liệu ActiveX được tham chiếu, bạn có vài tùy chọn. Sử dụng các giá trị của adStateOpen liên tục từ ObjectStateEnum

If Not (rs Is Nothing) Then 
    If (rs.State And 1) = 1 Then rs.Close 
    Set rs = Nothing 
End If 

Hoặc bạn có thể xác định hằng số cho mình để làm cho mã của bạn dễ đọc hơn (định nghĩa chúng tất cả cho một ví dụ điển hình.)

Const adStateClosed As Long = 0 'Indicates that the object is closed. 
Const adStateOpen As Long = 1 'Indicates that the object is open. 
Const adStateConnecting As Long = 2 'Indicates that the object is connecting. 
Const adStateExecuting As Long = 4 'Indicates that the object is executing a command. 
Const adStateFetching As Long = 8 'Indicates that the rows of the object are being retrieved.  

[...] 

If Not (rs Is Nothing) Then 

    ' ex. If (0001 And 0001) = 0001 (only open flag) -> true 
    ' ex. If (1001 And 0001) = 0001 (open and retrieve) -> true 
    ' This second example means it is open, but its value is not 1 
    ' and If rs.State = 1 -> false, even though it is open 
    If (rs.State And adStateOpen) = adStateOpen Then 
     rs.Close 
    End If 

    Set rs = Nothing 
End If 

Answer 2

Chủ đề này là cũ nhưng nếu những người khác như tôi tìm kiếm giải pháp, đây là giải pháp mà tôi đã tìm thấy:

Public Function DBStats() As Boolean 
    On Error GoTo errorHandler 
     If Not IsNull(myBase.Version) Then 
      DBStats = True 
     End If 
     Exit Function 
    errorHandler: 
     DBStats = False 
End Function 

Vì vậy "myBase" là đối tượng cơ sở dữ liệu, tôi h ave đã tạo một lớp để truy cập vào cơ sở dữ liệu (lớp có chèn, cập nhật, vv ...) và trên mô-đun mà lớp đó sử dụng khai báo trong một đối tượng (rõ ràng) và tôi có thể kiểm tra kết nối với "[đối tượng] .DBStats":

Dim BaseAccess As New myClass 
BaseAccess.DBOpen 'I open connection 
Debug.Print BaseAccess.DBStats ' I test and that tell me true 
BaseAccess.DBClose ' I close the connection 
Debug.Print BaseAccess.DBStats ' I test and tell me false 

chỉnh sửa: trong DBOpen tôi sử dụng "OpenDatabase" và trong DBClose tôi sử dụng ".Close" và 'thiết lập MyBase = không có gì' chỉnh sửa 2: trong chức năng, nếu bạn không kết nối, .version cung cấp cho bạn một lỗi vì vậy nếu không kết nối, errorHandler cung cấp cho bạn false