Giá trị trích xuất Clojure từ bản đồ dựa trên logic được ưu tiên

Question

Tôi có một chức năng muốn kéo giá trị ra khỏi bản đồ dựa trên thứ tự ưu tiên. Hiện tại tôi đang làm nó như một cấu trúc lồng nhau nếu là khủng khiếp. Tôi phải tin rằng có một cách tốt hơn.

Trong khi tác phẩm này có cách nào tốt hơn?

(defn filter-relatives [relatives] 
    (if(contains? relatives :self) 
     (relatives :self) 
      (if(contains? relatives :north) 
       (relatives :north) 
        (if(contains? relatives :west) 
         (relatives :west) 
         (if(contains? relatives :east) 
          (relatives :east) 
          (relatives :south) 
         ) 
        ) 
       ) 
      ) 
     ) 
    ) 
) 

Answer 1

(some relatives [:self :north :west :east :south]) 

Answer 2

gì về:

(defn filter-relatives [relatives ordered-filters] 
    (first (filter identity (map relatives ordered-filters)))) 

mẫu chạy:

user=> (filter-relatives {:a 1 :b 2 :c 3} [:z :b :a])                
2 

Answer 3

Những câu trả lời khác cũng tốt nếu nil và false không nằm trong số các giá trị có thể. Nếu có, bạn có thể sử dụng một cái gì đó như

(if-let [e (some (partial find relatives) 
       [:self :north :west :east :south])] 
    (val e) 
    :no-key-found) 

Ví dụ:

(if-let [e (some (partial find relatives) 
       [:self :north :west :east :south])] 
    (val e) 
    :no-key-found) 
; => false 

(if-let [e (some (partial find {}) 
       [:self :north :west :east :south])] 
    (val e) 
    :no-key-found) 
; => :no-key-found 

Answer 4

(first (keep relatives [:self :north :west :east :south]))