Làm thế nào để có được một đầu ra của một chương trình Exec'ed trong cài đặt Inno?

Question

Có thể nhận được kết quả đầu ra của tệp thực thi có hiệu lực là Exec không?

Tôi muốn hiển thị cho người dùng trang truy vấn thông tin, nhưng hiển thị giá trị mặc định của địa chỉ MAC trong hộp nhập. Có cách nào khác để đạt được điều này không?

Answer 1

Vâng, sử dụng chuyển hướng của đầu ra tiêu chuẩn vào một tệp:

[Code] 

function NextButtonClick(CurPage: Integer): Boolean; 
var 
    TmpFileName, ExecStdout: string; 
    ResultCode: integer; 
begin 
    if CurPage = wpWelcome then begin 
    TmpFileName := ExpandConstant('{tmp}') + '\ipconfig_results.txt'; 
    Exec('cmd.exe', '/C ipconfig /ALL > "' + TmpFileName + '"', '', SW_HIDE, 
     ewWaitUntilTerminated, ResultCode); 
    if LoadStringFromFile(TmpFileName, ExecStdout) then begin 
     MsgBox(ExecStdout, mbInformation, MB_OK); 
     { do something with contents of file... } 
    end; 
    DeleteFile(TmpFileName); 
    end; 
    Result := True; 
end; 

Lưu ý rằng có thể có nhiều hơn một bộ chuyển đổi mạng, và hậu quả là nhiều địa chỉ MAC để lựa chọn.

Answer 2

Tôi phải làm như vậy (thực hiện lệnh gọi dòng lệnh và nhận kết quả) và đưa ra giải pháp tổng quát hơn.

Nó cũng sửa lỗi lạ nếu đường dẫn được trích dẫn được sử dụng trong các cuộc gọi thực tế bằng cách sử dụng cờ /S cho cmd.exe.

{ Exec with output stored in result. } 
{ ResultString will only be altered if True is returned. } 
function ExecWithResult(const Filename, Params, WorkingDir: String; const ShowCmd: Integer; 
    const Wait: TExecWait; var ResultCode: Integer; var ResultString: String): Boolean; 
var 
    TempFilename: String; 
    Command: String; 
begin 
    TempFilename := ExpandConstant('{tmp}\~execwithresult.txt'); 
    { Exec via cmd and redirect output to file. Must use special string-behavior to work. } 
    Command := 
    Format('"%s" /S /C ""%s" %s > "%s""', [ 
     ExpandConstant('{cmd}'), Filename, Params, TempFilename]); 
    Result := Exec(ExpandConstant('{cmd}'), Command, WorkingDir, ShowCmd, Wait, ResultCode); 
    if not Result then 
    Exit; 
    LoadStringFromFile(TempFilename, ResultString); { Cannot fail } 
    DeleteFile(TempFilename); 
    { Remove new-line at the end } 
    if (Length(ResultString) >= 2) and (ResultString[Length(ResultString) - 1] = #13) and 
    (ResultString[Length(ResultString)] = #10) then 
    Delete(ResultString, Length(ResultString) - 1, 2); 
end; 

Cách sử dụng:

Success := 
    ExecWithResult('ipconfig', '/all', '', SW_HIDE, ewWaitUntilTerminated, 
    ResultCode, ExecStdout) or 
    (ResultCode <> 0); 

Kết quả cũng có thể được nạp vào một đối tượng TStringList để có được tất cả các dòng:

Lines := TStringList.Create; 
Lines.Text := ExecStdout; 
{ ... some code ... } 
Lines.Free;