Cách chuyển một cột của bảng thành chuỗi csv trong SQL Server mà không cần sử dụng con trỏ

Question

Tôi muốn trả lại kết quả của select Column from Table thành chuỗi được phân tách bằng dấu phẩy bằng cách sử dụng SQL Server.

Cột được đề cập khá lớn (nvarchar(2000)) vì vậy giải pháp phải có khả năng xử lý các giá trị kết quả rất lớn.

Answer 1

DECLARE @result nvarchar(max) 
SET @result = '' 

SELECT @result = @result + [Column] + N',' 
FROM [TABLE] 

--TODO: trim last ',' if you require 

PRINT @result 

Nếu Column có thể được null, sau đó, hoặc loại trừ nó lần đầu tiên, hoặc sử dụng ISNULL/COALESCE - nếu không một đơn NULL sẽ phá vỡ toàn bộ chuỗi. Đó là hiệu quả hơn để loại trừ nó với một WHERE:

SELECT @result = @result + [Column] + N',' 
FROM [TABLE] 
WHERE [Column] IS NOT NULL 

Answer 2

mà không có phiên bản dấu phẩy:

declare @s varchar(max); 

select @s = isnull(@s + ', ' + lastname, lastname) 
from person 
order by lastname; 

print @s; 

Answer 3

Tôi đã tạo một proc rằng động sẽ tạo ra một CSV ra khỏi bất kỳ bảng tùy ý, mà không cần chỉ định rõ ràng các cột. Điều này rất hữu ích nếu bạn không muốn viết mã tùy chỉnh mỗi lần bạn muốn biến một bảng SQL thành một chuỗi CSV.

-- Description: Turns a query into a formatted CSV. 
-- Any ORDER BY clause needs to be passed in the separate ORDER BY parameter. 
CREATE PROC [dbo].[spQueryToCsv] 
(
    @query nvarchar(MAX), --A query to turn into CSV format. It should not include an ORDER BY clause. 
    @orderBy nvarchar(MAX) = NULL, --An optional ORDER BY clause. It should contain the words 'ORDER BY'. 
    @csv nvarchar(MAX) = NULL OUTPUT --The CSV output of the procedure. 
) 
AS 
BEGIN 
    SET NOCOUNT ON; 

    IF @orderBy IS NULL BEGIN 
    SET @orderBy = ''; 
    END 

    SET @orderBy = REPLACE(@orderBy, '''', ''''''); 

    DECLARE @realQuery nvarchar(MAX) = ' 
    DECLARE @headerRow nvarchar(MAX); 
    DECLARE @cols nvarchar(MAX); 

    SELECT * INTO #dynSql FROM (' + @query + ') sub;  

    SELECT @cols = ISNULL(@cols + '' + '''','''' + '', '''') + ''''''"'''' + ISNULL(REPLACE(CAST(['' + name + ''] AS nvarchar(max)), ''''"'''', ''''""''''), '''''''') + ''''"'''''' 
    FROM tempdb.sys.columns 
    WHERE object_id = object_id(''tempdb..#dynSql'') 
    ORDER BY column_id;   

    SET @cols = '' 
     SET @csv = (SELECT '' + @cols + '' FROM #dynSql ' + @orderBy + ' FOR XML PATH(''''m_m'''')); 
     '' 
    EXEC sys.sp_executesql @cols, N''@csv nvarchar(MAX) OUTPUT'', @csv=@csv OUTPUT  

    SELECT @headerRow = ISNULL(@headerRow + '','', '''') + ''"'' + REPLACE(name, ''"'', ''""'') + ''"'' 
    FROM tempdb.sys.columns 
    WHERE object_id = object_id(''tempdb..#dynSql'') 
    ORDER BY column_id; 

    SET @headerRow = @headerRow + CHAR(13) + CHAR(10); 

    SET @csv = @headerRow + @csv;  
    '; 

    EXEC sys.sp_executesql @realQuery, N'@csv nvarchar(MAX) OUTPUT', @csv=@csv OUTPUT 
    SET @csv = REPLACE(REPLACE(@csv, '<m_m>', ''), '</m_m>', CHAR(13) + CHAR(10)) 
END 

GO 

Cách sử dụng:

DECLARE @csv nvarchar(max) 
EXEC [dbo].[spQueryToCsv] @query = 'SELECT * FROM Customers', @csv = @csv OUTPUT, @orderBy = 'ORDER BY CustomerId' 
SELECT @csv 

này được dựa trên mã tương tự như tôi đã viết để biến một bảng tùy ý vào một HTML string.