Tải xuống tệp AIR AS3 bị hỏng khi băng thông thấp

Question

Tôi đang sử dụng lớp Trình tải xuống để nhận tệp lớn từ máy chủ IIS trên WS2012 và xử lý tiến trình tải xuống.

Nó hoạt động tốt, tuy nhiên khi băng thông của khách hàng quá bão hòa, sự kiện Progress không được kích hoạt nữa và sau một khoảng thời gian tải xuống chỉ dừng lại (sự kiện hoàn tất có vẻ được kích hoạt?), Mặc dù tải xuống chưa hoàn thành, để lại khách hàng với một tập tin bị hỏng.

tôi không thể tìm ra cách để giải quyết việc này, hoặc thậm chí những gì chiến lược tôi nên dùng về vấn đề này (kết thúc việc tải xuống và hiển thị một lỗi? Chờ cho băng thông sẵn có để có được mảnh tiếp theo của tôi byte?)

đây là lớp Downloader.as

public class Downloader extends EventDispatcher 
{ 
    [Event(name="DownloadComplete", type="DownloadEvent")] 

    public static var spd:int = 0; 
    private var file:File; 
    private var fileStream:FileStream; 
    private var url:String; 
    private var urlStream:URLStream; 

    var mc_background:MovieClip; 
    var howManyTimes:Number = 3; //How many times per second the download speed will be traced 
    var bytesLoaded:Number = 0; //don't change, necessary for calculation 
    var lastTime:int = 0; //don't change, necessary for calculation 


    private var waitingForDataToWrite:Boolean = false; 

    public function Downloader(s:MovieClip) 
    { 
     mc_background = s; 

     lastTime = getTimer(); 
     urlStream = new URLStream(); 

     urlStream.addEventListener(Event.OPEN, onOpenEvent); 
     urlStream.addEventListener(ProgressEvent.PROGRESS, onProgressEvent); 
     urlStream.addEventListener(Event.COMPLETE, onCompleteEvent); 

     fileStream = new FileStream(); 
     fileStream.addEventListener(OutputProgressEvent.OUTPUT_PROGRESS, writeProgressHandler) 

    } 

    public function download(formUrl:String, toFile:File):void { 
     this.url = formUrl; 
     this.file = toFile; 
     mc_background.pb.file_txt.text = file.name; 
     fileStream.openAsync(file, FileMode.WRITE); 
     urlStream.load(new URLRequest(url)); 
    } 

    private function onOpenEvent(event:Event):void { 
     waitingForDataToWrite = true; 

     dispatchEvent(event.clone()); 
    } 

    private function onProgressEvent(event:ProgressEvent):void { 
     var time:int = getTimer(); 
     if(time - lastTime >= (1000/howManyTimes)) 
     { 
      var kiloBytes:Number = (event.bytesLoaded - bytesLoaded)/1000; 
      var timeInSecs:Number = (time - lastTime)/1000; 

      var kbsPerSecVal:Number = Math.floor(kiloBytes/timeInSecs); 
      trace(kbsPerSecVal + " kbs/s"); 

      mc_background.pb.speed_txt.text = kbsPerSecVal + " kbs/s"; 
      bytesLoaded = event.bytesLoaded; 
      lastTime = getTimer(); 
     } 
     if(waitingForDataToWrite){ 
      writeToDisk(); 
      dispatchEvent(event.clone()); 
     } 
    } 

    private function writeToDisk():void { 
     var fileData:ByteArray = new ByteArray(); 
     urlStream.readBytes(fileData, 0, urlStream.bytesAvailable); 
     fileStream.writeBytes(fileData,0,fileData.length); 
     waitingForDataToWrite = false; 

     dispatchEvent(new DataEvent(DataEvent.DATA)); 
    } 

    private function writeProgressHandler(evt:OutputProgressEvent):void{ 
     waitingForDataToWrite = true; 
    } 

    private function onCompleteEvent(event:Event):void { 
     if(urlStream.bytesAvailable>0) 
      writeToDisk(); 
     fileStream.close(); 

     fileStream.removeEventListener(OutputProgressEvent.OUTPUT_PROGRESS, writeProgressHandler); 

     dispatchEvent(event.clone()); 
     // dispatch additional DownloadEvent 
     dispatchEvent(new DownloadEvent(DownloadEvent.DOWNLOAD_COMPLETE, url, file)); 
    } 

} 

Answer 1

hãy thử một biến int mà các cửa hàng dự kiến ​​filesize ..

Khi tổ chức sự kiện cháy Hoàn bây giờ kiểm tra nếu [tải về] của bạn fileData.length bằng expected_FileSize.

Nếu ít thì thử lại cho đến khi bằng hoặc bất cứ điều gì là đủ tốt. Để nhận được từ số byte cuối cùng, bạn sử dụng "yêu cầu phạm vi" trong tiêu đề yêu cầu. Nó cũng được hiển thị trong liên kết này Nếu điều đó giúp bạn.

Thứ gì đó như URLRequestHeader("range","bytes="+startPOS+"-"+endPOS); trong đó startPOS là datata.length + 1 và endPos được mong đợi_FileSize số tiền.