vim - các khung phân tách không hoạt động

Question

Nếu bạn đã quen với ứng dụng iTerm2, bạn sẽ biết rằng bạn có thể tách các chế độ xem tương tự như vim và các chế độ xem không hoạt động bị "làm mờ".

Tôi thường làm việc trong vim với ba chế độ xem chia dọc và sẽ tốt hơn nếu làm mờ các màu không hoạt động bằng cách đặt màu nền thành tông màu tối hơn, ví dụ.

Có cách nào để thực hiện việc này không?

Answer 1

tôi đã đưa ra các giải pháp sau đây (sử dụng 'colorcolumn' và unset 'cursorline'):

" Dim inactive windows using 'colorcolumn' setting 
" This tends to slow down redrawing, but is very useful. 
" Based on https://groups.google.com/d/msg/vim_use/IJU-Vk-QLJE/xz4hjPjCRBUJ 
" XXX: this will only work with lines containing text (i.e. not '~') 
function! s:DimInactiveWindows() 
    for i in range(1, tabpagewinnr(tabpagenr(), '$')) 
    let l:range = "" 
    if i != winnr() 
     if &wrap 
     " HACK: when wrapping lines is enabled, we use the maximum number 
     " of columns getting highlighted. This might get calculated by 
     " looking for the longest visible line and using a multiple of 
     " winwidth(). 
     let l:width=256 " max 
     else 
     let l:width=winwidth(i) 
     endif 
     let l:range = join(range(1, l:width), ',') 
    endif 
    call setwinvar(i, '&colorcolumn', l:range) 
    endfor 
endfunction 
augroup DimInactiveWindows 
    au! 
    au WinEnter * call s:DimInactiveWindows() 
    au WinEnter * set cursorline 
    au WinLeave * set nocursorline 
augroup END 

Xem nó ở tôi dotfiles (hiện tại): https://github.com/blueyed/dotfiles/blob/master/vimrc#L351

Cập nhật tôi đã tạo một plugin trong số đó: https://github.com/blueyed/vim-diminactive

Answer 2

Thay đổi màu nền như bạn mô tả sẽ đòi hỏi colourschemes khác nhau cho các cửa sổ Vim khác nhau. Theo tôi biết điều này là không thể, vì nó là một thiết lập toàn cầu (xem this answer từ một vài ngày trước).

Là một trợ giúp trực quan mà cửa sổ đang hoạt động, tôi thấy trạng thái là đủ thông thường. Các nhóm nổi bật khác nhau đối với cửa sổ hiện hoạt (hi StatusLine) và bất kỳ cửa sổ không hoạt động nào (hi StatusLineNC). Bạn có thể chọn một colourscheme với một constrast rất stark giữa chúng, hoặc chỉnh sửa colourscheme yêu thích của bạn.

Answer 3

Trong neovim (v0.2.1), cấu hình sau sẽ làm mờ các khung không hoạt động:

hi ActiveWindow ctermbg=16 | hi InactiveWindow ctermbg=233 
set winhighlight=Normal:ActiveWindow,NormalNC:InactiveWindow