Làm thế nào để viết hello world trong assembler trong Windows?

Question

Tôi muốn viết một cái gì đó cơ bản trong lắp ráp trong Windows, tôi đang sử dụng NASM, nhưng tôi không thể nhận được bất cứ điều gì làm việc.

Làm cách nào để viết và biên dịch hello world mà không có sự trợ giúp của các chức năng C trên Windows?

Answer 1

NASM examples.

; ---------------------------------------------------------------------------- 
; helloworld.asm 
; 
; This is a Win32 console program that writes "Hello, World" on one line and 
; then exits. It needs to be linked with a C library. 
; ---------------------------------------------------------------------------- 

    global _main 
    extern _printf 

    section .text 
_main: 
    push message 
    call _printf 
    add  esp, 4 
    ret 
message: 
    db 'Hello, World', 10, 0 

Sau đó chạy

nasm -fwin32 helloworld.asm 
gcc helloworld.obj 
a 

Ngoài ra còn có The Clueless Newbies Guide to Hello World in Nasm mà không sử dụng một thư viện C. Sau đó, mã sẽ trông như thế này.

org 100h 
mov dx,msg 
mov ah,9 
int 21h 
mov ah,4Ch 
int 21h 
msg db 'Hello, World!',0Dh,0Ah,'$' 

Chúc may mắn.

Answer 2

Ví dụ này cho biết cách truy cập trực tiếp vào API Windows và không liên kết trong Thư viện chuẩn C.

global _main 
    extern _GetStdHandle@4 
    extern _WriteFile@20 
    extern _ExitProcess@4 

    section .text 
_main: 
    ; DWORD bytes;  
    mov  ebp, esp 
    sub  esp, 4 

    ; hStdOut = GetstdHandle(STD_OUTPUT_HANDLE) 
    push -11 
    call _GetStdHandle@4 
    mov  ebx, eax  

    ; WriteFile(hstdOut, message, length(message), &bytes, 0); 
    push 0 
    lea  eax, [ebp-4] 
    push eax 
    push (message_end - message) 
    push message 
    push ebx 
    call _WriteFile@20 

    ; ExitProcess(0) 
    push 0 
    call _ExitProcess@4 

    ; never here 
    hlt 
message: 
    db  'Hello, World', 10 
message_end: 

Để biên dịch, bạn sẽ cần NASM và link.exe (từ Visual studio Standard Edition)

 
    nasm -fwin32 hello.asm 
    link /subsystem:console /nodefaultlib /entry:main hello.obj 

Answer 3

Trừ khi bạn gọi hàm một số đây không phải là ở tất cả tầm thường. (Và, nghiêm túc, không có sự khác biệt thực sự về sự phức tạp giữa việc gọi printf và gọi hàm win32 api.)

Ngay cả khi DOS int 21h thực sự chỉ là một cuộc gọi hàm, ngay cả khi một API khác.

Nếu bạn muốn làm điều đó mà không cần trợ giúp, bạn cần phải nói chuyện trực tiếp với phần cứng video của mình, có khả năng viết bitmap của các chữ cái "Hello world" vào bộ đệm khung. Thậm chí sau đó card màn hình đang làm công việc dịch các giá trị bộ nhớ đó thành tín hiệu VGA/DVI. Lưu ý rằng, thực sự, không có công cụ nào trong số tất cả các công cụ này xuống phần cứng là thú vị hơn trong ASM so với C. Một chương trình "hello world" sôi xuống một cuộc gọi hàm. Một điều tốt đẹp về ASM là bạn có thể sử dụng bất kỳ ABI nào bạn muốn khá dễ dàng; bạn chỉ cần biết ABI đó là gì.

Answer 4

Đây là các ví dụ về Win32 và Win64 sử dụng các cuộc gọi Windows API. Chúng dành cho MASM chứ không phải là NASM, nhưng hãy xem chúng. Bạn có thể tìm thêm chi tiết trong this bài viết.

;---ASM Hello World Win32 MessageBox 

.386 
.model flat, stdcall 
include kernel32.inc 
includelib kernel32.lib 
include user32.inc 
includelib user32.lib 

.data 
title db 'Win32', 0 
msg db 'Hello World', 0 

.code 

Main: 
push 0   ; uType = MB_OK 
push offset title ; LPCSTR lpCaption 
push offset msg ; LPCSTR lpText 
push 0   ; hWnd = HWND_DESKTOP 
call MessageBoxA 
push eax   ; uExitCode = MessageBox(...) 
call ExitProcess 

End Main 

;---ASM Hello World Win64 MessageBox 

extrn MessageBoxA: PROC 
extrn ExitProcess: PROC 

.data 
title db 'Win64', 0 
msg db 'Hello World!', 0 

.code 
main proc 
    sub rsp, 28h 
    mov rcx, 0  ; hWnd = HWND_DESKTOP 
    lea rdx, msg  ; LPCSTR lpText 
    lea r8, title ; LPCSTR lpCaption 
    mov r9d, 0  ; uType = MB_OK 
    call MessageBoxA 
    add rsp, 28h 
    mov ecx, eax  ; uExitCode = MessageBox(...) 
    call ExitProcess 
main endp 

End 

Để lắp ráp và liên kết các sử dụng MASM, sử dụng cho 32-bit thực thi:

ml.exe [filename] /link /subsystem:windows 
/defaultlib:kernel32.lib /defaultlib:user32.lib /entry:Main 

hay này cho 64-bit thực thi:

ml64.exe [filename] /link /subsystem:windows 
/defaultlib:kernel32.lib /defaultlib:user32.lib /entry:main 

Answer 5

Nếu bạn muốn sử dụng trình liên kết NASM và Visual Studio (link.exe) với ví dụ Hello World của anderstornvig, bạn sẽ phải liên kết theo cách thủ công với C Runtime Libary chứa hàm printf().

nasm -fwin32 helloworld.asm 
link.exe helloworld.obj libcmt.lib 

Hy vọng điều này sẽ giúp ai đó.

Answer 6

Flat Assembler không cần thêm trình liên kết. Điều này làm cho lập trình assembler khá dễ dàng. Nó cũng có sẵn cho Linux.

Đây là hello.asm từ các ví dụ Fasm:

include 'win32ax.inc' 

.code 

    start: 
    invoke MessageBox,HWND_DESKTOP,"Hi! I'm the example program!",invoke GetCommandLine,MB_OK 
    invoke ExitProcess,0 

.end start 

Fasm tạo ra một thực thi:

 
>fasm hello.asm 
flat assembler version 1.70.03 (1048575 kilobytes memory) 
4 passes, 1536 bytes. 

Và đây là chương trình trong IDA:

Bạn có thể xem ba cal ls: GetCommandLine, MessageBox và ExitProcess.

Answer 7

Để có được một .exe với NASM'compiler và mối liên kết Visual Studio của mã này hoạt động tốt:

global WinMain 
extern ExitProcess ; external functions in system libraries 
extern MessageBoxA 

section .data 
title: db 'Win64', 0 
msg: db 'Hello world!', 0 

section .text 
WinMain: 
    sub rsp, 28h 
    mov rcx, 0  ; hWnd = HWND_DESKTOP 
    lea rdx,[msg] ; LPCSTR lpText 
    lea r8,[title] ; LPCSTR lpCaption 
    mov r9d, 0  ; uType = MB_OK 
    call MessageBoxA 
    add rsp, 28h 

    mov ecx,eax 
    call ExitProcess 

    hlt  ; never here 

Nếu mã này được lưu trên ví dụ "Test64.asm", sau đó để biên dịch:

nasm -f win64 test64.asm 

Tạo "test64.obj" Sau đó, để liên kết từ dấu nhắc lệnh:

path_to_link\link.exe test64.obj /subsystem:windows /entry:WinMain /libpath:path_to_libs /nodefaultlib kernel32.lib user32.lib /largeaddressaware:no 

nơi path_to_link có thể C: \ Program Files (x86) \ Microsoft Visual Studio 10.0 \ VC \ bin hoặc bất cứ đâu là chương trình link.exe trong máy của bạn, path_to_libs có thể là C: \ Program Files (x86) \ Windows Kits \ 8.1 \ Lib \ winv6. 3 \ um \ x64 hoặc bất kỳ thư viện nào của bạn (trong trường hợp này cả kernel32.lib và user32.lib đều ở cùng một nơi, nếu không thì hãy sử dụng một tùy chọn cho mỗi đường dẫn bạn cần) và /largeaddressaware: không có tùy chọn để tránh khiếu nại của liên kết về địa chỉ dài (đối với user32.lib trong trường hợp này). Ngoài ra, vì nó được thực hiện ở đây, nếu liên kết của Visual được gọi từ dấu nhắc lệnh, nó là cần thiết để thiết lập môi trường trước đó (chạy một lần vcvarsall.bat và/hoặc xem MS C++ 2010 and mspdb100.dll).

Answer 8

Ví dụ tốt nhất là những người bị co thắt, vì co thắt không sử dụng trình liên kết, điều này làm ẩn đi sự phức tạp của các cửa sổ lập trình bởi một lớp phức tạp mờ đục khác. Nếu bạn đang hài lòng với một chương trình viết vào cửa sổ gui, thì có một ví dụ cho chương trình đó trong thư mục ví dụ của fasm.

Nếu bạn muốn một chương trình bảng điều khiển, cho phép chuyển hướng tiêu chuẩn và tiêu chuẩn ra cũng có thể. Có một chương trình ví dụ (helas rất không tầm thường) có sẵn mà không sử dụng một gui, và làm việc chặt chẽ với bàn điều khiển, đó là chính nó. Điều này có thể được làm mỏng ra các yếu tố cần thiết. (Tôi đã viết một trình biên dịch ra đó là một ví dụ không gui, nhưng nó cũng không tầm thường).

Chương trình như vậy có lệnh sau để tạo tiêu đề thực thi phù hợp, thường được thực hiện bởi trình liên kết.

FORMAT PE CONSOLE 

Một phần được gọi là '.idata' chứa bảng giúp các cửa sổ trong khi khởi động để ghép tên các hàm vào địa chỉ thời gian chạy.Nó cũng chứa một tham chiếu đến KERNEL.DLL là hệ điều hành Windows.

section '.idata' import data readable writeable 
... 

Chương trình của bạn nằm trong phần '.text'. Nếu bạn khai báo phần đó có thể đọc được và có thể thực thi được, đó là phần duy nhất bạn cần.

section '.text' code executable readable writable 

Bạn có thể gọi cho tất cả các cơ sở bạn khai báo trong phần .idata. Đối với một chương trình giao diện điều khiển, bạn cần _GetStdHandle để tìm các trình biên dịch cho tiêu chuẩn và tiêu chuẩn (sử dụng các tên biểu tượng như STD_INPUT_HANDLE mà fasm tìm thấy trong tệp win32a.inc bao gồm). Một khi bạn có các bộ mô tả tập tin, bạn có thể thực hiện WriteFile và ReadFile. Tất cả các chức năng được mô tả trong tài liệu kernel32. Bạn có thể nhận thức được điều đó hoặc bạn sẽ không cố gắng lập trình lắp ráp.

Tóm lại: Có một bảng có tên asci mà cặp vợ chồng đến hệ điều hành windows. Trong khi khởi động, công cụ này được chuyển thành một bảng địa chỉ có thể gọi, mà bạn sử dụng trong chương trình của mình.