Lưu dưới dạng XML với VBA?

Question

Có cách nào để lưu bảng Excel dưới dạng XML không? Tôi có tệp XML Schema ... và một số dữ liệu trong một bảng ... và tôi có trong Excel tùy chọn Lưu dưới dạng tệp XML nhưng tôi có thể lưu một tệp dưới dạng XML từ VBA không? Tôi muốn tự động hóa một quá trình và tôi không tìm thấy gì trên tùy chọn này. Cảm ơn!

Answer 1

macro recorder ol tốt' đã cứu tôi lần này :)) (Tại sao tôi không sử dụng nó trước khi tôi được đăng ở đây) Vậy ... Để tải một schema xml bạn có:?

ActiveWorkbook.XmlMaps.Add("Book2.xml", "raport").Name _ 
     = "raport_Map" 

Và để lưu nó dưới dạng xml:

ActiveWorkbook.SaveAsXMLData Filename:="Book3.xml", _ 
     Map:=ActiveWorkbook.XmlMaps("raport_Map") 

Ai có thể nghĩ rằng đó là dễ dàng?

Answer 2

Liên kết này đã giúp tôi nhiều nhất ->http://curiousmind.jlion.com/exceltotextfile

Script vào liên kết:

Sub MakeXML(iCaptionRow As Integer, iDataStartRow As Integer, sOutputFileName As String) 
    Dim Q As String 
    Q = Chr$(34) 

    Dim sXML As String 

    sXML = "<?xml version=" & Q & "1.0" & Q & " encoding=" & Q & "UTF-8" & Q & "?>" 
    sXML = sXML & "<rows>" 


    ''--determine count of columns 
    Dim iColCount As Integer 
    iColCount = 1 
    While Trim$(Cells(iCaptionRow, iColCount)) > "" 
     iColCount = iColCount + 1 
    Wend 

    Dim iRow As Integer 
    iRow = iDataStartRow 

    While Cells(iRow, 1) > "" 
     sXML = sXML & "<row id=" & Q & iRow & Q & ">" 

     For icol = 1 To iColCount - 1 
      sXML = sXML & "<" & Trim$(Cells(iCaptionRow, icol)) & ">" 
      sXML = sXML & Trim$(Cells(iRow, icol)) 
      sXML = sXML & "</" & Trim$(Cells(iCaptionRow, icol)) & ">" 
     Next 

     sXML = sXML & "</row>" 
     iRow = iRow + 1 
    Wend 
    sXML = sXML & "</rows>" 

    Dim nDestFile As Integer, sText As String 

    ''Close any open text files 
    Close 

    ''Get the number of the next free text file 
    nDestFile = FreeFile 

    ''Write the entire file to sText 
    Open sOutputFileName For Output As #nDestFile 
    Print #nDestFile, sXML 
    Close 
End Sub 

Sub test() 
    MakeXML 1, 2, "C:\Users\jlynds\output2.xml" 
End Sub