Vim chỉ lọc lựa chọn trực quan không phải toàn bộ dòng

Question

Tôi muốn lọc một lựa chọn trực quan trong Vim thông qua một lệnh. Con đường tôi biết luôn lọc các dòng hoàn toàn mà lựa chọn hình ảnh mở rộng:

Chọn a test trong dòng

this is a test 

và gõ

:'<,'>!echo "the result" 

sẽ dẫn đến

the result 

Nhưng tôi muốn:

this is the result 

Answer 1

Hãy xem xét các ánh xạ sau đó tuân thủ các hành vi của các ! linewise lệnh lọc (xem :helpg \*!\* và :help v_!).

nnoremap <silent> <leader>! :set opfunc=ProgramFilter<cr>g@ 
vnoremap <silent> <leader>! :<c-u>call ProgramFilter(visualmode(), 1)<cr> 
function! ProgramFilter(vt, ...) 
    let [qr, qt] = [getreg('"'), getregtype('"')] 
    let [oai, ocin, osi, oinde] = [&ai, &cin, &si, &inde] 
    setl noai nocin nosi inde= 

    let [sm, em] = ['[<'[a:0], ']>'[a:0]] 
    exe 'norm!`' . sm . a:vt . '`' . em . 'x' 

    call inputsave() 
    let cmd = input('!') 
    call inputrestore() 

    let out = system(cmd, @") 
    let out = substitute(out, '\n$', '', '') 
    exe "norm!i\<c-r>=out\r" 

    let [&ai, &cin, &si, &inde] = [oai, ocin, osi, oinde] 
    call setreg('"', qr, qt) 
endfunction 

Answer 2

Bạn có thể sử dụng \%V để phù hợp với bên trong khu vực trực quan:

:'<,'>s/\%V.*\%V/\=system('echo -n "the result"')