Làm cách nào để gửi dữ liệu bài đăng và tiêu đề bằng Chromium?

Question

Tôi đang cố chuyển đổi một số mã từ TWebBrowser sang Chromium nhưng gặp sự cố khi tìm cách gửi dữ liệu bài đăng và tiêu đề bằng yêu cầu HTTP.

Dưới đây là chức năng TWebBrowser mà tôi đang cố triển khai.

var 
VHeader, PostData: OleVariant; 


PostData := VarArrayCreate([0, Length(XMLString) - 1], varByte) ;  
HeaderData := 'Content-Type: application/x-www-form-urlencoded'+ '\n'; 

WebBrowser1.Navigate(StrUrl,EmptyParam,EmptyParam,PostData,VHeader); 

Làm cách nào để làm tương đương với Chromium?

Answer 1

Do tài liệu bị thiếu cho Delphi Chromium Embedded, tôi sẽ tham khảo các yêu cầu cần thiết để gửi yêu cầu web cho phiên bản C++ của CEF. Vì vậy, bạn cần sử dụng phương thức LoadRequest để gửi yêu cầu trong Chromium. Để sử dụng nó, bạn cần thể hiện đối tượng của lớp đối tượng yêu cầu CefRequest cùng với các đối tượng HeaderMap và CefPostData cho tiêu đề yêu cầu và đặc tả dữ liệu.

Mở rộng trên Henri Gourvest của (tác giả của wrapper Delphi CEF) ví dụ từ this thread, bạn có thể trong Delphi thử một cái gì đó giống như pseudo-code sau:

uses 
    ceflib; 

function CreateField(const AValue: AnsiString): ICefPostDataElement; 
begin 
    Result := TCefPostDataElementRef.New; 
    Result.SetToBytes(Length(AValue), PAnsiChar(AValue)); 
end; 

procedure TForm1.Button1Click(Sender: TObject); 
var 
    Header: ICefStringMultimap; 
    Data: ICefPostData; 
    Request: ICefRequest; 
begin 
    Header := TCefStringMultimapOwn.Create; 
    Header.Append('Content-Type', 'application/x-www-form-urlencoded'); 

    Data := TCefPostDataRef.New; 
    Data.AddElement(CreateField('Data.id=27')); 
    Data.AddElement(CreateField('&Data.title=title')); 
    Data.AddElement(CreateField('&Data.body=body')); 

    Request := TCefRequestRef.New; 
    Request.Flags := WUR_FLAG_NONE; 
    Request.Assign('http://example.com/', 'POST', Data, Header); 

    Chromium1.Browser.MainFrame.LoadRequest(Request); 
end; 

Cùng nên làm một phiên bản khác của các mã trên :

procedure TForm1.Button1Click(Sender: TObject); 
var 
    Header: ICefStringMultimap; 
    Data: ICefPostData; 
    Request: ICefRequest; 
begin 
    Request := TCefRequestRef.New; 
    Request.Url := 'http://example.com/'; 
    Request.Method := 'POST'; 
    Request.Flags := WUR_FLAG_NONE; 

    Header := TCefStringMultimapOwn.Create; 
    Header.Append('Content-Type', 'application/x-www-form-urlencoded'); 
    Request.SetHeaderMap(Header); 

    Data := TCefPostDataRef.New; 
    Data.AddElement(CreateField('Data.id=27')); 
    Data.AddElement(CreateField('&Data.title=title')); 
    Data.AddElement(CreateField('&Data.body=body')); 
    Request.PostData := Data; 

    Chromium1.Browser.MainFrame.LoadRequest(Request); 
end;