vợt: sử dụng các sự kiện trong một cửa sổ khung%

Question

tôi đang học vợt (trước đây là PLT Scheme, một phương ngữ LISP) và cố gắng khám phá làm thế nào để xử lý các sự kiện khác nhau hơn paint-callback (có thể nó không phải là ngay cả một).

Tôi hy vọng rất nhiều từ this part of the doc nhưng on-char và on-event dường như không làm gì có thể làm tôi quan tâm (hoặc không có gì cả).

Ngoài ra, tôi không hiểu các không gian sự kiện, gọi lại hàng đợi và cách sử dụng của chúng. Một ví dụ sẽ là một điều tuyệt vời! Tôi sẽ biết ơn người đàn ông tốt đẹp sẽ viết cho tôi một cái :).

Dưới đây là mã của tôi:

(define game (new frame%)) 

(define gameLay (class canvas% (super-new))) 

(new gameLay 
    [parent game] 
    [paint-callback (λ (canvas dc) #|draw things|#)]) 

Tôi muốn sử dụng một cái gì đó như "on-chuột-nhấp chuột trái" (mà không tồn tại) cách tôi sử dụng "sơn-callback" nhưng tôi nghĩ rằng tôi cần phải thêm các bước (Tôi đã đọc về các sự kiện vv). Tôi biết nó không hoạt động nhưng đây là mã giả thuyết tôi đang tìm kiếm:

(new gameLay 
    [parent game] 
    [paint-callback (λ (canvas dc) #|draw things|#)] 
    [on-mouse-click-left (λ (canvas dc) #|do other things|#)]) 

Answer 1

Dưới đây là một chương trình nhỏ sử dụng bức tranh sơn dầu và các sự kiện bàn phím. Khi bạn đã nhấn phím mũi tên, canvas sẽ hiển thị phím cuối cùng bạn đã nhấn.

#lang racket/gui 

(define game-canvas% 
    (class canvas% 
    (inherit get-width get-height refresh) 

    ;; direction : one of #f, 'left, 'right, 'up, 'down 
    (define direction #f) 

    (define/override (on-char ke) 
     (case (send ke get-key-code) 
     [(left right up down) 
     (set! direction (send ke get-key-code)) 
     (refresh)] 
     [else (void)])) 

    (define/private (my-paint-callback self dc) 
     (let ([w (get-width)] 
      [h (get-height)]) 
     (when direction 
      (let ([dir-text (format "going ~a" direction)]) 
      (let-values ([(tw th _ta _td) 
          (send dc get-text-extent dir-text)]) 
       (send dc draw-text 
        dir-text 
        (max 0 (/ (- w tw) 2)) 
        (max 0 (/ (- h th) 2)))))))) 

    (super-new (paint-callback (lambda (c dc) (my-paint-callback c dc)))))) 

(define game-frame (new frame% (label "game") (width 600) (height 400))) 
(define game-canvas (new game-canvas% (parent game-frame))) 
(send game-frame show #t) 

Mọi khung hình đều có một không gian sự kiện quản lý việc gửi sự kiện. Phương thức on-char là một trình xử lý sự kiện; nó được chạy trong chuỗi xử lý sự kiện. Sẽ không có sự kiện nào khác được xử lý cho đến khi phương thức on-char của bạn kết thúc. Vì vậy, nếu bạn muốn làm một cái gì đó phức tạp, bạn có thể muốn tạo một thread riêng biệt và thực hiện tính toán ở đó. Một cách đơn giản để làm điều đó là tạo một không gian sự kiện khác, một không gian xử lý sự kiện cho bất kỳ khung nào, nhưng điều đó xử lý "sự kiện" bạn gửi nó bằng cách sử dụng queue-callback. Ví dụ, thay đổi định nghĩa của on-char trên với điều này:

(define aux-eventspace (make-eventspace)) 

(define/override (on-char ke) 
    (parameterize ((current-eventspace aux-eventspace)) 
    (queue-callback 
    (lambda() 
     (case (send ke get-key-code) 
     ((left right up down) 
      (set! direction (send ke get-key-code)) 
      (refresh)) 
     (else (void))))))) 

Chức năng trao cho queue-callback được chạy trong một thread riêng biệt. Bạn có thể chèn một số bản in, sự chậm trễ, hoặc bất cứ điều gì để thuyết phục bản thân rằng không gian sự kiện chính vẫn có thể xử lý các sự kiện trong khi người kia xử lý cuộc gọi lại của bạn.