Phiên bản tiêu chuẩn hoặc sử dụng thành ngữ (fn [f & args] (áp dụng f args))

Question

Mỗi lần như vậy, tôi thường muốn áp dụng một tập hợp các hàm trên một số tập hợp tham số. Thật dễ dàng để làm với bản đồ và một chức năng rất đơn giản.

(map 
    (fn invoke [f & args] (apply f args)) 
    [- + *] 
    [1 2 3] 
    [1 2 3] 
    [1 2 3]) 

(-1 6 27) 

Tìm kiếm trên web có một vài thư viện xác định chức năng tương tự, thường được gọi là funcall hoặc gọi. Bởi vì thiên hướng của Clojure cho các hàm variadic, tôi không thể không nghĩ rằng nên có một phiên bản mặc định của hàm này.

Có hay không có cách nào khác để giải quyết các tình huống như thế này?

Edit:

hình thức khác có thể là

(map 
    (comp eval list) 
    [- + *] 
    [1 2 3] 
    [1 2 3] 
    [1 2 3]) 

(-1 6 27) 

nào làm tôi sợ vì eval.

Answer 1

Không có chức năng funcall hoặc tương đương trong thư viện Clojure chuẩn hoạt động chính xác theo cách này. "áp dụng" là khá gần nhưng cần một bộ sưu tập các đối số ở cuối chứ không phải thuần túy là variadic.

Với điều này trong tâm trí, bạn có thể "ăn gian" với áp dụng để làm cho nó hoạt động như sau bằng cách thêm một danh sách vô hạn của Nils đến cùng (mà được coi là chuỗi rỗng của các đối số bổ sung):

(map apply [- + *] [1 2 3] [1 2 3] [1 2 3] (repeat nil)) 
=> (-1 6 27) 

Nhìn chung, tôi nghĩ rằng cách tiếp cận hợp lý nếu bạn thực sự muốn sử dụng chức năng này thường xuyên chỉ là để xác định nó:

(defn funcall [f & ps] 
    (apply f ps)) 

(map funcall [- + *] [1 2 3] [1 2 3] [1 2 3]) 
=> (-1 6 27) 

Answer 2

Edit: này sẽ làm những gì bạn muốn (như @BrandonH đề cập):

(map #(apply %1 %&) [- + *] [1 2 3] [1 2 3] [1 2 3]) 

Nhưng điều này là hầu như không một sự cải tiến so với phiên bản của bạn - nó chỉ sử dụng một cách viết tắt cho các chức năng ẩn danh.

---

sự hiểu biết của tôi là FUNCALL là cần thiết trong Common Lisp, vì nó là một Lisp-2, trong khi Clojure là một Lisp-1.

Answer 3

Hiện tại, tôi không thể sử dụng chức năng clojure.core mà bạn có thể cắm vào bản đồ của mình và thực hiện theo những gì bạn muốn. Vì vậy, tôi muốn nói, chỉ cần sử dụng phiên bản của riêng bạn.

Matt có lẽ là đúng rằng lý do không có một funcall, là bạn hầu như không bao giờ cần đến nó trong một Lisp-1 (có nghĩa là, chức năng và các ràng buộc khác chia sẻ không gian cùng tên trong clojure)

Answer 4

(map #(%1 %2 %3 %4) [- + *][1 2 3][1 2 3][1 2 3]) 

(-1 6 27) 

Vấn đề là nếu bạn muốn cho phép một số biến đối số, cú pháp & đặt các giá trị trong vec-tơ, yêu cầu sử dụng áp dụng. Giải pháp của bạn có vẻ ổn với tôi nhưng như Brandon H đã chỉ ra, bạn có thể rút ngắn giải pháp đó thành #(apply %1 %&).

Là người trả lời khác đã lưu ý, nó không có gì để làm với funcall mà tôi nghĩ được sử dụng trong Lisps khác để tránh sự nhập nhằng giữa các ký hiệu và chức năng (lưu ý rằng tôi gọi là chức năng như (%1 ...) ở đây, không (funcall %1 ...).

Answer 5

Nếu bạn thực sự không có một đầu mối về tên hàm, nhưng bạn biết những gì trong và đầu ra phải được, bạn có thể thử https://github.com/Raynes/findfn.

(find-arg [-1 6 27] map '% [- + *] [1 2 3] [1 2 3] [1 2 3]) 
;=> (clojure.core/trampoline) 

này cho chúng ta biết

(map trampoline [- + *] [1 2 3] [1 2 3] [1 2 3]) 
;=> (-1 6 27) 

Thực ra, bạn có thể lạm dụng tấm bạt lò xo như funcall trong clojure. Nhưng nó hầu như không thành ngữ, bởi vì nó là một Lisp-1.Mã trên đánh giá đến:

[(trampoline - 1 1 1), (trampoline + 2 2 2), (trampoline * 3 3 3)] mà sau đó trở thành [-1 6 27] (dưới hình thức của lazyseq chính xác).

Như Adrian Mouat chỉ ra trong bình luận dưới đây, điều này có lẽ không phải là cách ưu tiên để giải quyết nó. Sử dụng một funcall như xây dựng có mùi hơi buồn cười. Phải có một giải pháp sạch hơn. Cho đến khi bạn thấy rằng, findfn có thể hữu ích ;-).

Answer 6

Cá nhân tôi nghĩ phiên bản đầu tiên của bạn khá rõ ràng và thành ngữ.

Dưới đây là một sự thay thế, bạn có thể tìm thấy thú vị để xem xét tuy nhiên:

(map 
    apply 
    [- + *] 
    (map vector [1 2 3] [1 2 3] [1 2 3])) 

=> (-1 6 27) 

Lưu ý lừa của việc sử dụng (vector bản đồ ....) để transpose chuỗi các đối số vào ([1 1 1] [2 2 2] [3 3 3]) để chúng có thể được sử dụng trong hàm áp dụng.

Answer 7

Điều gì về điều này? Nó chọn các giá trị trả về có liên quan từ juxt. Vì đây là tất cả lười biếng, nó chỉ nên tính toán các yếu tố cần thiết.

user> (defn my-juxt [fns & colls] 
     (map-indexed (fn [i e] (e i)) 
      (apply map (apply juxt fns) colls))) 
#'user/my-juxt 
user> (my-juxt [- + *] [1 2 3] [1 2 3] [1 2 3]) 
(-1 6 27) 

Answer 8

Một cách tiếp cận đó là khá tự giải thích: "đối với từng chức năng thứ n, áp dụng nó cho tất cả các yếu tố thứ n của các vectơ":

(defn my-juxt [fun-vec & val-vecs] 
    (for [n (range 0 (count fun-vec))] 
    (apply (fun-vec n) (map #(nth % n) val-vecs)))) 

user> (my-juxt [- + *] [1 2 3] [1 2 3] [1 2 3]) 
(-1 6 27)