Ví dụ đối tượng tham chiếu được tạo bằng cách sử dụng "with" trong Delphi

Question

có cách nào để tham chiếu một cá thể đối tượng được tạo bằng câu lệnh "with" không?

Ví dụ:

with TAnObject.Create do 
begin 
    DoSomething(instance); 
end; 

đâu DoSomething sẽ sử dụng tài liệu tham khảo ví dụ như khi bạn đang đi qua một thể hiện từ một biến khai báo tham chiếu đến các đối tượng được tạo ra.

Ví dụ:

AnObject := TAnObject.Create; 

Cảm ơn.

Answer 1

Bạn không bao giờ nên sử dụng with do thay đổi trong tương lai có thể giới thiệu nhiều hơn về phạm vi đó so với bạn dự định.

Cầm lấy cái này ví dụ:

procedure Test; 
var 
    x: Integer; 
begin 
    with TSomeObject.Create do 
    begin 
     DoSomethingWithX(x); 
     Free; 
    end; 
end; 

và sau đó sau này bạn gài trên một tài sản X trên lớp TSomeObject. Bây giờ, bạn nghĩ nó sẽ sử dụng cái gì? Biến cục bộ hoặc thuộc tính X của đối tượng?

Giải pháp tốt nhất là luôn tạo một biến cục bộ có tên ngắn và đặt bí danh đối tượng cho biến đó.

procedure Test; 
var 
    x: Integer; 
    o: TSomeObject; 
begin 
    o := TSomeObject.Create; 
    o.DoSomethingWithX(x); 
    o.Free; 
end; 

Answer 2

Vâng, bạn có thể sử dụng cách tiếp cận như vậy:

// implement: 

type 
    TSimpleMethod = procedure of object; 

function GetThis(const pr: TSimpleMethod): TObject; 
begin 
    Result := TMethod(pr).Data; 
end; 

// usage: 

    with TStringList.Create do 
    try 
    CommaText := '1,2,3,4,5,6,7,8,9,0'; 
    ShowText(TStringList(GetThis(Free))); 
    finally 
    Free; 
    end; 

hoặc lớp người giúp đỡ:

type 
    TObjectHelper = class helper For TObject 
    private 
    function GetThis: TObject; Inline; 
    public 
    property This: TObject read GetThis; 
    end; 

... 

function TObjectHelper.GetThis: TObject; 
begin 
    Result := Self; 
end; 

Nhưng, trên thực tế, trả lời trước đó là chính xác: bạn nên quên hơn về "với" tuyên bố.

Answer 3

Tôi đã học được cách cứng - chỉ sử dụng 'Với' trong các tình huống sau:

With TMyForm.Create(Owner) do 
    try 
    ShowModal 
    finally 
    Free; 
    end; 


procedure Notify(Sender : TObject); 
begin 
    With Sender as TSomething do 
    VerySimpleProperty := Something  
end; 

tức là giữ cho tầm nhìn của Với như đơn giản càng tốt. Khi bạn đưa vào tài khoản thực tế là trình gỡ lỗi không thể giải quyết 'Với', nó thực sự tốt hơn và rõ ràng hơn để sử dụng biến cục bộ đơn giản hoặc để khai báo đầy đủ mục tiêu tức là MyRecord.Something

Answer 4

Bạn đã tự trả lời: khai báo biến cục bộ . Nếu bạn muốn, bạn có thể sử dụng với từ khóa trên đó.

var 
    MyInstance: TMyObject; 
begin 
    MyInstance := TMyObject.Create; 
    with MyInstance do 
    try 
    Foo; 
    Bar; 
    DoSomething(MyInstance); 
    finally 
    Free; 
    end; 
end; 

Trong ví dụ trên lý do duy nhất để sử dụng với là mã dễ đọc, mà là rất chủ quan, bạn cũng có thể mương với từ khóa và sử dụng MyInstance trực tiếp. Nó chỉ là vấn đề sở thích cá nhân. Tôi không đồng ý về câu trả lời "không bao giờ sử dụng với", nhưng bạn nên biết về những hạn chế của nó.

cũng Xem câu hỏi này: Is delphi "with" keyword a bad practice?

Answer 5

Một sự thêm vào ví dụ của Brian vào một handler Thông báo cho là sử dụng một biến tuyệt đối (chỉ win32):

procedure Notify(Sender : TObject); 
var 
    Something : TSomeThing absolute Sender; 
begin 
    if Sender is TSomething then 
    begin 
    VerySimpleProperty := Something.Something; 
    OtherProperty := Something.SomethingElse; 
    end; 
end; 

Về cơ bản nó tránh được việc phải gán một biến địa phương hoặc có rất nhiều loại phôi.

Answer 6

này là không thể, nhưng chúng ta có thể làm cho nó trở thành hiện thực bằng cách thuyết phục những người sáng tạo biên dịch:

With TForm1.Create (Nil) Do // New TForm1 instance 
    Try 
     LogForm ("); // That same instance as parameter to an outer method (solution) 
     "ShowModal; // Instance.ShowModal 
    Finally 
     "Free; // Instance.Free 
    End; 

đề nghị của tôi là:

1. Không nhiều hơn một đối tượng/hồ sơ cho mỗi Với tiêu đề .
2. Không được phép Nested Withs.
3. Sử dụng "để chỉ ra đối tượng/hồ sơ (dấu ngoặc kép tương tự như đến vạch ditto: http://en.wikipedia.org/wiki/Ditto_mark)..

Answer 7

Có một hack làm việc tốt để làm như vậy Xác định chức năng workaround này somwhere trong dự án đơn vị.

// use variable inside 'with ... do' 
// WSelf function returns TObject associated with its method. 
// I would recommend to use the method 'Free' 
// WSelf(Free) as <TObjectN> 
type TObjectMethod = procedure of object; 
function WSelf(const MethodPointer: TObjectMethod): TObject; 
begin 
    Result := TMethod(MethodPointer).Data; 
end; 

dụ sử dụng.

var 
    SL: TStringList; 
begin 
    SL := TStringList.Create; 
    try 
     with TStringList.Create do 
     try 
      Add('1'); 
      Add('2'); 
      Add('3'); 
      // (WSelf(Free) as TStringList) references to the object 
      // created by TStringList.Create 
      SL.Assign(WSelf(Free) as TStringList); 
     finally 
      Free; 
     end; 
    finally 
     ShowMessage(SL.Text); 
     SL.Free; 
    end; 
end;