Viết lại C# mã sử dụng Task.WhenAll trong F #

Question

tôi có phương pháp giao diện sau:

Task<string[]> GetBlobsFromContainer(string containerName); 

và thực hiện nó trong C#:

var container = await _containerClient.GetContainer(containerName); 
var tasks = container.ListBlobs() 
        .Cast<CloudBlockBlob>() 
        .Select(b => b.DownloadTextAsync()); 
return await Task.WhenAll(tasks); 

Khi tôi cố gắng viết lại nó trong F #:

member this.GetBlobsFromContainer(containerName : string) : Task<string[]> = 
    let task = async { 
     let! container = containerClient.GetContainer(containerName) |> Async.AwaitTask 
     return container.ListBlobs() 
       |> Seq.cast<CloudBlockBlob> 
       |> Seq.map (fun b -> b.DownloadTextAsync()) 
       |> ?? 
    } 
    task |> ?? 

Tôi đang mắc kẹt với các dòng cuối cùng.

Cách quay lại Task<string[]> từ F # đúng cách?

Answer 1

Tôi phải đoán loại containerClient là gì và gần nhất tôi thấy là CloudBlobClient (không có getContainer: string -> Task<CloubBlobContainer> nhưng không quá khó để thích ứng). Sau đó, chức năng của bạn có thể trông giống như sau:

open System 
open System.Threading.Tasks 
open Microsoft.WindowsAzure.Storage.Blob 
open Microsoft.WindowsAzure.Storage 

let containerClient : CloudBlobClient = null 

let GetBlobsFromContainer(containerName : string) : Task<string[]> = 
    async { 
     let container = containerClient.GetContainerReference(containerName) 
     return! container.ListBlobs() 
       |> Seq.cast<CloudBlockBlob> 
       |> Seq.map (fun b -> b.DownloadTextAsync() |> Async.AwaitTask) 
       |> Async.Parallel 
    } |> Async.StartAsTask 

Tôi đã thay đổi kiểu trả về là Task<string[]> thay vì Task<string seq> như tôi giả sử bạn muốn giữ lại giao diện. Nếu không, tôi khuyên bạn nên loại bỏ Task và sử dụng Async trong mã F # -only.

Answer 2

Điều này có hiệu quả không?

member this.GetBlobsFromContainer(containerName : string) : Task<string seq> = 
    let aMap f x = async { 
     let! a = x 
     return f a } 
    let task = async { 
     let! container = containerClient.GetContainer(containerName) |> Async.AwaitTask 
     return! container.ListBlobs() 
      |> Seq.cast<CloudBlockBlob> 
      |> Seq.map (fun b -> b.DownloadTextAsync() |> Async.AwaitTask) 
      |> Async.Parallel 
      |> aMap Array.toSeq 
    } 
    task |> Async.StartAsTask 

Tôi phải đưa ra một số giả định về containerClient v.v. vì vậy tôi chưa thể thử nghiệm điều này, nhưng ít nhất nó biên dịch.