Regex với biểu thức đệ quy để khớp với niềng răng lồng nhau?

Question

Tôi đang cố gắng khớp văn bản như sp { ...{...}... }, trong đó các dấu ngoặc nhọn được phép lồng. Đây là những gì tôi có cho đến thời điểm này:

my $regex = qr/ 
(     #save $1 
    sp\s+   #start Soar production 
    (    #save $2 
     \{   #opening brace 
     [^{}]*  #anything but braces 
     \}   #closing brace 
     | (?1)  #or nested braces 
    )+    #0 or more 
) 
/x; 

Tôi không thể làm cho nó khớp với văn bản sau đây: sp { { word } }. Bất cứ ai có thể nhìn thấy những gì là sai với regex của tôi?

Answer 1

Có nhiều sự cố. Bit đệ quy nên là:

(
    (?: \{ (?-1) \} 
    | [^{}]+ 
    )* 
) 

Tất cả với nhau:

my $regex = qr/ 
    sp\s+ 
    \{ 
     (
     (?: \{ (?-1) \} 
     | [^{}]++ 
     )* 
    ) 
    \} 
/x; 

print "$1\n" if 'sp { { word } }' =~ /($regex)/; 

Answer 2

Đây là trường hợp cho underused Text::Balanced, một mô-đun lõi rất tiện dụng cho các loại hình điều. Nó dựa trên pos của sự bắt đầu của chuỗi phân được tìm thấy/set đầu tiên, vì vậy tôi thường gọi nó như thế này:

#!/usr/bin/env perl 

use strict; 
use warnings; 

use Text::Balanced 'extract_bracketed'; 

sub get_bracketed { 
    my $str = shift; 

    # seek to beginning of bracket 
    return undef unless $str =~ /(sp\s+)(?={)/gc; 

    # store the prefix 
    my $prefix = $1; 

    # get everything from the start brace to the matching end brace 
    my ($bracketed) = extract_bracketed($str, '{}'); 

    # no closing brace found 
    return undef unless $bracketed; 

    # return the whole match 
    return $prefix . $bracketed; 
} 

my $str = 'sp { { word } }'; 

print get_bracketed $str; 

Các regex với modifier gc kể chuỗi để nhớ nơi điểm cuối của trận đấu là, và extract_bracketed sử dụng thông tin đó để biết bắt đầu từ đâu.