Làm thế nào để có được tên nhóm làm nổi bật dưới con trỏ trong vim?

Question

Tôi thường tùy chỉnh hiện tại colorscheme để đáp ứng nhu cầu của mình.

Nếu tôi có thể lấy tên nhóm cú pháp dưới con trỏ, nó sẽ giúp tôi rất nhiều, giống như Firebug nhưng trong Vim. Tôi muốn biết làm thế nào để làm điều đó.

Answer 1

Có chức năng này đã được nổi khắp nơi trên web khi tôi đã làm điều tương tự:

function! SynStack() 
    if !exists("*synstack") 
    return 
    endif 
    echo map(synstack(line('.'), col('.')), 'synIDattr(v:val, "name")') 
endfunc 

Answer 2

Hãy thử điều này:

" diagnostics {{{ 
if has('balloon_eval') 
    nnoremap <F12>   : setl beval!<CR> 
    set bexpr=InspectSynHL() 
endif 
fun! InspectSynHL() 
    let l:synNames = [] 
    let l:idx = 0 
    for id in synstack(v:beval_lnum, v:beval_col) 
     call add(l:synNames, printf('%s%s', repeat(' ', idx), synIDattr(id, 'name'))) 
     let l:idx+=1 
    endfor 
    return join(l:synNames, "\n") 
endfun 
"}}} 

Answer 3

Chức năng sau đây sẽ ra cả tên của cú pháp nhóm và nhóm cú pháp được dịch của ký tự mà con trỏ đang bật:

function! SynGroup()                
    let l:s = synID(line('.'), col('.'), 1)          
    echo synIDattr(l:s, 'name') . ' -> ' . synIDattr(synIDtrans(l:s), 'name') 
endfun 

Để làm cho điều này thuận tiện hơn, nó có thể được gói trong một lệnh tùy chỉnh hoặc ràng buộc khóa.

Làm thế nào các công trình này:

• line('.') và col('.') trả lại vị trí hiện tại
• synID(...) trả về một ID cú pháp số
• synIDtrans(l:s) dịch cú pháp id số l:s bằng cách làm theo nổi bật liên kết
• synIDattr(l:s, 'name') trả về tên tương ứng với cú pháp số ID

này sẽ echo cái gì đó như:

vimMapModKey -> Special