Tôi có thể khớp với ký tự đại diện của nhà xây dựng dữ liệu trong Haskell không?

Question

Tôi có

data Foo = X (String, Int) | A String | B String | C String | D String -- ... 

và đã xác định

f (X (s, _)) =s 
f (A s) = s 
f (B s) = s 
f (C s) = s 
f (D s) = s 
-- ... 

nhưng muốn để có thể viết một cái gì đó giống như

f (X (s, _)) =s 
f (_ s) = s 

Nhưng có vẻ là không có cách nào để làm điều này (tôi nhận được "lỗi phân tích cú pháp" được liên kết với số _).

Có cách nào để khớp với ký tự đại diện của nhà xây dựng dữ liệu trong Haskell không?

Answer 1

Không. Nhưng bạn có thể viết điều này:

data Foo 
    = X { name :: String, age :: Int } 
    | A { name :: String } 
    | B { name :: String } 
    | C { name :: String } 
    | D { name :: String } 

và sau đó có name :: Foo -> String. Bạn cũng có thể xem xét điều này:

data Tag = A | B | C | D 
data Foo = X String Int | Tagged Tag String 

f (X s _) = s 
f (Tagged _ s) = s 

Answer 2

Ngoài câu trả lời của @ DanielWagner, cách khác là sử dụng Scrap your boilerplate (AKA "SYB"). Nó cho phép bạn tìm thấy subterm đầu tiên của một loại nhất định. Vì vậy, bạn có thể xác định

{-# LANGUAGE DeriveDataTypeable #-} 

import Control.Monad 
import Data.Data 
import Data.Generics.Schemes 
import Data.Typeable 

data Foo = X (String, Int) | A String | B String | C String | D String 
    deriving (Show, Eq, Ord, Data, Typeable) 

fooString :: Foo -> Maybe String 
fooString = msum . gmapQ cast 

và fooString sẽ trả lại đối số đầu tiên String của các nhà thầu của bạn. Chức năng cast lọc ra String s và gmapQ nhận các giá trị được lọc cho tất cả các lớp con ngay lập tức.

Tuy nhiên, điều này sẽ không trả lại String từ X, vì X không có ngay lập tức String subterm, nó chỉ có một subterm loại (String, Int). Để có được String đầu tiên bất cứ nơi nào trong hệ thống phân cấp hạn, bạn có thể sử dụng everywhere:

fooString' :: Foo -> Maybe String 
fooString' = everything mplus cast 

Lưu ý rằng phương pháp này là hơi mong manh: Nó bao gồm đơn giản là tất cả String là nó tìm thấy, trong đó có thể không phải luôn luôn những gì bạn muốn , đặc biệt, nếu sau này bạn mở rộng kiểu dữ liệu của mình (hoặc một số kiểu dữ liệu mà nó tham chiếu).