Thêm hai bản đồ vào Groovy khi tổng hợp các giá trị cho các phím chung

Question

Tôi có hai bản đồ trong Groovy [a: 1, b: 2] và [b:1, c:3] và muốn tạo từ các bản đồ thứ ba [a: 1, b: 3, c: 3]. Có lệnh Groovy thực hiện điều đó không?

Chỉnh sửa: Lưu ý rằng các giá trị trong bản đồ thứ ba là tổng của các giá trị từ hai bản đồ đầu tiên, nếu các phím giống hệt nhau.

Cảm ơn

Answer 1

Tuy nhiên, một giải pháp khác sẽ be:

def m1 = [ a:1, b:2 ] 
def m2 = [ b:1, c:3 ] 

def newMap = [m1,m2]*.keySet().flatten().unique().collectEntries { 
    [ (it): [m1,m2]*.get(it).findAll().sum() ] 
} 

Lấy epidemian's answer như inspiriation, bạn cũng có thể viết một phương pháp để xử lý nhiều bản đồ

def m1 = [a: 1, b: 2] 
def m2 = [b: 1, c: 3] 

def combine(Map... m) { 
    m.collectMany { it.entrySet() }.inject([:]) { result, e -> 
    result << [ (e.key):e.value + (result[ e.key ] ?: 0) ] 
    } 
} 

def newMap = combine(m1, m2) 

Answer 2

Tôi không nghĩ rằng có một phương pháp làm sẵn cho điều này, có lẽ sử dụng một cái gì đó như:

def m1 = [a: 1, b: 2] 
def m2 = [b: 1, c: 3] 
def newMap = (m1.keySet() + m2.keySet()).inject([:]) { 
    acc, k -> acc[k] = (m1[k] ?: 0) + (m2[k] ?: 0); acc 
} 

Answer 3

này làm nó:

Map additionJoin(Map map1, Map map2) 
{ 
    def result = [:]; 
    result.putAll(map1); 
    result.putAll(map2); 

    result.each { key, value -> 
    if(map1[key] && map2[key]) 
    { 
     result[key] = map1[key] + map2[key] 
    } 
    } 

    return result; 
} 

def a = [a: 1, b: 2] 
def b = [b:1,c:3] 

def c = additionJoin(a, b) 

println c 

Answer 4

này nên làm việc cho bất kỳ số lượng bản đồ:

def maps = [[a: 1, b: 2], [b:1, c:3]] 

def result = [:].withDefault{0} 
maps.collectMany{ it.entrySet() }.each{ result[it.key] += it.value } 

assert result == [a: 1, b: 3, c: 3] 

Khái niệm maps.collectMany{ it.entrySet() } trả về một danh sách các mục bản đồ, như [a=1, b=2, b=1, c=3], và sau đó mỗi người trong số đó được thêm vào kết quả.

Một tùy chọn khác, nếu bạn muốn giữ tất cả biến đổi thành một biểu thức và làm cho nó "thêm chức năng", trước tiên hãy nhóm các mục theo khóa và sau đó tổng hợp các giá trị, nhưng tôi nghĩ nó ít có thể đọc được:

def result = maps.collectMany{ it.entrySet() } 
    .groupBy{ it.key } 
    .collectEntries{[it.key, it.value.sum{ it.value }]} 

phần groupBy trả về một bản đồ có dạng [a:[a=1], b:[b=2, b=1], c:[c=3]] và sau đó là collectEntries biến đổi mà bản đồ vào nhau mà có Kays tương tự nhưng có tổng các danh sách trong các giá trị thay thế.

Answer 5

Một cách tốt đẹp là nó sử dụng toán tử lây lan:

def m1 = [ a:1, b:2 ] 
def m2 = [ b:1, c:3 ] 
def m3 = [ *:m1, *:m2 ] 

println "m1 = $m1" 
println "m2 = $m2" 
println "m3 = $m3" 

* Credit: http://mrhaki.blogspot.ch/2009/09/groovy-goodness-spread-operator.html

Đoạn mã trên không hoạt động trong groovysh nhưng nó là tốt trong giao diện điều khiển groovy. (Đối với phiên bản 1.8)

Answer 6

Ví dụ dưới đây trình bày thêm hai bản đồ, một bản đồ thứ ba m3:

Map m1 = [ a:1, b:2 ]; 
Map m2 = [ b:1, c:3 ]; 
Map m3 = [:]; 
m3 << m1 
m3 << m2 

Answer 7

def merge(map1, map2) { 
    def add = { map, entry -> map << entry } 
    map2.inject(map1.inject([:], add), add) 
}