chuỗi Parsing trong tập tin batch

Question

Tôi có chuỗi sau:

MyProject/Architecture=32bit,BuildType=Debug,OS=winpc

Tôi muốn để có thể lấy các giá trị 32bit, Debug, và WinPC và lưu trữ chúng trong các biến có tên là Kiến trúc, BuildType, và Hệ điều hành để tham khảo sau này trong tập lệnh batch. Tôi thường là một người Unix nên đây là lãnh thổ mới cho tôi. Mọi sự trợ giúp sẽ rất được trân trọng!

Answer 1

này nên làm điều đó:

FOR /F "tokens=1-6 delims==," %%I IN ("MyProject/Architecture=32bit,BuildType=Debug,OS=winpc") DO (
    ECHO I %%I, J %%J, K %%K, L %%L, M %%M, N %%N 
) 
REM output is: I MyProject/Architecture, J 32bit, K BuildType, L Debug, M OS, N winpc 

Lô FOR vòng lặp là một phần khá thú vị của máy móc. Nhập FOR /? trong bảng điều khiển để mô tả một số nội dung thú vị mà công cụ này có thể thực hiện.

Answer 2

Hãy thử như sau:

@ECHO OFF 

SET Var=MyProject/Architecture=32bit,BuildType=Debug,OS=winpc 

FOR /F "tokens=1,2,3 delims=," %%A IN ("%Var%") DO (
    FOR /F "tokens=1,2 delims==" %%D IN ("%%A") DO (
     SET Architecture=%%E 
    ) 
    FOR /F "tokens=1,2 delims==" %%D IN ("%%B") DO (
     SET BuildType=%%E 
    ) 
    FOR /F "tokens=1,2 delims==" %%D IN ("%%C") DO (
     SET OS=%%E 
    ) 
) 

ECHO %Architecture% 
ECHO %BuildType% 
ECHO %OS% 

PAUSE 

Answer 3

Dưới đây là một giải pháp thú vị mà không quan tâm có bao nhiêu hoặc những gì đặt tên = giá trị cặp được quy định. Bí quyết là thay thế mỗi dấu phẩy bằng ký tự linefeed để FOR/F sẽ lặp lại từng cặp name = value. Điều này sẽ hoạt động miễn là chỉ có một / trong chuỗi.

@echo off 
setlocal enableDelayedExpansion 
set "str=MyProject/Architecture=32bit,BuildType=Debug,OS=winpc" 

::Eliminate the leading project info 
set "str=%str:*/=%" 

::Define a variable containing a LineFeed character 
set LF=^ 


::The above 2 empty lines are critical - do not remove 

::Parse and set the values 
for %%A in ("!LF!") do (
    for /f "eol== tokens=1,2 delims==" %%B in ("!str:,=%%~A!") do set "%%B=%%C" 
) 

::Display the values 
echo Architecture=%Architecture% 
echo BuildType=%BuildType% 
echo OS=%OS% 

Với mã bit hơn, nó có thể phân tích cú pháp một cách có chọn lọc chỉ các cặp tên = giá trị mà chúng tôi quan tâm.

@echo off 
setlocal enableDelayedExpansion 
set "str=MyProject/Architecture=32bit,BuildType=Debug,OS=winpc" 

::Eliminate the leading project info 
set "str=%str:*/=%" 

::Define a variable containing a LineFeed character 
set LF=^ 


::The above 2 empty lines are critical - do not remove 

::Define the variables we are interested in 
set "vars=Architecture BuildType OS" 

::Clear any existing values 
for %%A in (%vars%) do set "%%A=" 

::Set the values 
for %%A in ("!LF!") do (
    for /f "eol== tokens=1,2 delims==" %%B in ("!str:,=%%~A!") do (
    for %%D in (%vars%) do if "%%B"=="%%D" set "%%B=%%C" 
) 
) 

::Display the values 
for %%A in (%vars%) do echo %%A=!%%A!