Làm cách nào để có các ngày Tạo Tệp, Truy cập và Sửa đổi giống như các thuộc tính windows?

Question

tôi đang cố gắng để có được tạo, ngày truy cập và thay đổi giống như xuất hiện trong cửa sổ thuộc tính như trong:

Nhưng đang tìm kiếm thời gian được tính liên tục trong 30 phút ra:

Tin tưởng rằng nó có thể có liên quan đến tiết kiệm múi giờ/ánh sáng ban ngày nhưng không thể tìm được giải pháp. Đã cố gắng tìm kiếm tại địa chỉ: TimeZone Bias và điều chỉnh và xem xét phương pháp khác nhau bao gồm: How to get create/last modified dates of a file in Delphi?

đang hiện tại:

var 
MyFd TWin32FindData; 
FName: string; 
MyTime: TFileTime; 
MySysTime: TSystemTime; 
myDate, CreateTime, AccessTime, ModTime: TDateTime; 
Begin 
... 
FindFirstFile(PChar(FName), MyFd); 
MyTime:=MyFd.ftCreationTime; 
FileTimeToSystemTime(MyTime, MySysTime); 
myDate := EncodeDateTime(MySysTime.wYear, MySysTime.wMonth, MySysTime.wDay, MySysTime.wHour, 
MySysTime.wMinute, MySysTime.wSecond, MySysTime.wMilliseconds); 
Memo1.Lines.Add('Created: '+ FormatDateTime('dddd, d mmmm yyyy, hh:mm:ss ampm', MyDate)); 
... 

Bất kỳ giúp đánh giá cao

Cảm ơn Paul

Answer 1

Tôi không chắc chắn có gì sai với mã hiện tại của bạn, nhưng tôi tin rằng mã này sẽ làm những gì bạn cần, bằng cách sử dụng các cuộc gọi API chuẩn của Windows.

procedure TMyForm.ReportFileTimes(const FileName: string); 

    procedure ReportTime(const Name: string; const FileTime: TFileTime); 
    var 
    SystemTime, LocalTime: TSystemTime; 
    begin 
    if not FileTimeToSystemTime(FileTime, SystemTime) then 
     RaiseLastOSError; 
    if not SystemTimeToTzSpecificLocalTime(nil, SystemTime, LocalTime) then 
     RaiseLastOSError; 
    Memo1.Lines.Add(Name + ': ' + DateTimeToStr(SystemTimeToDateTime(LocalTime))); 
    end; 

var 
    fad: TWin32FileAttributeData; 

begin 
    if not GetFileAttributesEx(PChar(FileName), GetFileExInfoStandard, @fad) then 
    RaiseLastOSError; 
    Memo1.Clear; 
    Memo1.Lines.Add(FileName); 
    ReportTime('Created', fad.ftCreationTime); 
    ReportTime('Modified', fad.ftLastWriteTime); 
    ReportTime('Accessed', fad.ftLastAccessTime); 
end; 

procedure TMyForm.Button1Click(Sender: TObject); 
begin 
    ReportFileTimes(Edit1.Text); 
end; 

Answer 2

Bạn nên có thể sử dụng mã bên dưới để chuyển đổi giá trị ngày giờ UTC thành câu chuyện ngày giờ địa phương:

uses 
    Windows; 

function UTCTimeToLocalTime(const aValue: TDateTime): TDateTime; 
var 
    lBias: Integer; 
    lTZI: TTimeZoneInformation; 
begin 
    lBias := 0; 
    case GetTimeZoneInformation(lTZI) of 
    TIME_ZONE_ID_UNKNOWN: 
     lBias := lTZI.Bias; 
    TIME_ZONE_ID_DAYLIGHT: 
     lBias := lTZI.Bias + lTZI.DaylightBias; 
    TIME_ZONE_ID_STANDARD: 
     lBias := lTZI.Bias + lTZI.StandardBias; 
    end; 
    // UTC = local time + bias 
    // bias is in number of minutes, TDateTime is in days 
    Result := aValue - (lBias/(24 * 60)); 
end; 

Đánh giá từ hình ảnh bù đắp của bạn thực sự là 10 giờ 30 phút. Bạn có ở Nam Úc không?