chênh giờ chỉ trong vài giây

Question

Trong một chương trình Perl Tôi có một biến chứa ngày/giờ ở định dạng này:

Feb 3 12:03:20 

tôi cần phải xác định xem ngày đó là hơn x giây cũ (dựa trên thời gian hiện tại), ngay cả khi điều này xảy ra vào nửa đêm (ví dụ: Feb 3 23:59:00 với thời gian hiện tại = Feb 4 00:00:30).

Thông tin ngày/giờ perl tôi đã tìm thấy là tâm-boggling. Gần như tôi có thể nói tôi cần sử dụng Date::Calc, nhưng tôi không tìm thấy một giây-delta. Cảm ơn :)

Answer 1

Trong perl, luôn có nhiều cách để làm điều gì đó. Dưới đây là một trong đó chỉ sử dụng một mô-đun mà đến tiêu chuẩn với Perl:

#! perl -w 

use strict; 
use Time::Local; 

my $d1 = "Feb 3 12:03:20"; 
my $d2 = "Feb 4 00:00:30"; 

# Your date formats don't include the year, so 
# figure out some kind of default. 
use constant Year => 2012; 


# Convert your date strings to Unix/perl style time in seconds 
# The main problems you have here are: 
# * parsing the date formats 
# * converting the month string to a number from 1 to 11 
sub convert 
{ 
    my $dstring = shift; 

    my %m = ('Jan' => 0, 'Feb' => 1, 'Mar' => 2, 'Apr' => 3, 
      'May' => 4, 'Jun' => 5, 'Jul' => 6, 'Aug' => 7, 
      'Sep' => 8, 'Oct' => 9, 'Nov' => 10, 'Dec' => 11); 

    if ($dstring =~ /(\S+)\s+(\d+)\s+(\d{2}):(\d{2}):(\d{2})/) 
    { 
     my ($month, $day, $h, $m, $s) = ($1, $2, $3, $4, $5); 
     my $mnumber = $m{$month}; # production code should handle errors here 

     timelocal($s, $m, $h, $day, $mnumber, Year - 1900); 
    } 
    else 
    { 
     die "Format not recognized: ", $dstring, "\n"; 
    } 
} 

my $t1 = convert($d1); 
my $t2 = convert($d2); 

print "Diff (seconds) = ", $t2 - $t1, "\n"; 

Để làm điều này thực sự sản xuất-sẵn sàng, nó cần xử lý tốt hơn trong năm (ví dụ, những gì sẽ xảy ra khi ngày bắt đầu trong tháng Mười Hai và cuối vào tháng 1?) và xử lý lỗi tốt hơn (ví dụ: điều gì sẽ xảy ra nếu viết tắt 3 tháng của từ bị viết sai chính tả?).

Answer 2

Dường như có sự tiện lợi Date::Parse. Dưới đây là ví dụ:

use Date::Parse; 

print str2time ('Feb 3 12:03:20') . "\n"; 

Và đây là những gì nó ra:

$ perl test.pl 
1328288600 

đó là: Fri Feb 3 12:03:20 EST 2012

Tôi không chắc chắn như thế nào phong nha các phân tích cú pháp, nhưng nó phân tích ví dụ của bạn chỉ fine :)

Answer 3

Giả sử bạn muốn sử dụng Date::Calc, chuyển đổi hai giá trị thành giá trị "thời gian" với Date_to_Time và s ubtract các giá trị để có được sự khác biệt trong vài giây. Nhưng để thực hiện việc này, bạn cần phải chuyển đổi từ các chuỗi thành các giá trị YY MM DD hh mm ss để vượt qua trước tiên là Date_to_Time.

Answer 4

Với tinh thần TMTOWTDI, bạn có thể tận dụng lõi Time::Piece:

#!/usr/bin/env perl 
use strict; 
use warnings; 
use Time::Piece; 
my $when = "@ARGV" or die "'Mon Day HH:MM:SS' expected\n"; 
my $year = (localtime)[5] + 1900; 
my $t = Time::Piece->strptime($year . q() . $when, "%Y %b %d %H:%M:%S"); 
print "delta seconds = ", time() - $t->strftime("%s"),"\n"; 

$ ./mydelta Feb 3 12:03:20

delta seconds = 14553 

Các năm nay được giả định và lấy từ giờ địa phương của bạn.

Answer 5

#!/usr/bin/perl 

$Start = time(); 
sleep 3; 
$End = time(); 
$Diff = $End - $Start; 

print "Start ".$Start."\n"; 
print "End ".$End."\n"; 
print "Diff ".$Diff."\n"; 

Đây là cách đơn giản để tìm sự khác biệt về thời gian tính bằng giây.