phương pháp ReplaceLine trong VBE chỉ thay thế một phần của dòng

Question

Để đối phó với this câu hỏi tôi nghĩ rằng nó sẽ là thú vị để viết một macro VBE đó sẽ tự động thay thế dòng mà trông giống như

DimAll a, b, c, d As Integer 

bởi

Trong bản nháp đầu tiên của tôi, tôi chỉ muốn sửa đổi một dòng được chọn. Sau khi thiết lập các tài liệu tham khảo phù hợp để có được mô hình VBE đối tượng (xem http://www.cpearson.com/excel/vbe.aspx) và chơi xung quanh một chút tôi đã đưa ra:

Function ExpandDim(codeLine As String) As String 
    Dim fragments As Variant 
    Dim i As Long, n As Long, myType As String 
    Dim last As Variant 
    Dim expanded As String 

    If UCase(codeLine) Like "*DIMALL*AS*" Then 
     codeLine = Replace(codeLine, "dimall", "Dim", , , vbTextCompare) 
     fragments = Split(codeLine, ",") 
     n = UBound(fragments) 
     last = Split(Trim(fragments(n))) 
     myType = last(UBound(last)) 
     For i = 0 To n - 1 'excludes last fragment 
      expanded = expanded & IIf(i = 0, "", ",") & fragments(i) & " As " & myType 
     Next i 
     expanded = expanded & IIf(n > 0, ",", "") & fragments(n) 
     ExpandDim = expanded 
    Else 
     ExpandDim = codeLine 
    End If 
End Function 

Sub DimAll() 
    Dim myVBE As VBE 
    Dim startLine As Long, startCol As Long 
    Dim endLine As Long, endCol As Long 
    Dim myLine As String 
    Set myVBE = Application.VBE 
    myVBE.ActiveCodePane.GetSelection startLine, startCol, endLine, endCol 
    myLine = myVBE.ActiveCodePane.CodeModule.Lines(startLine, 1) 
    Debug.Print ExpandDim(myLine) 
    myVBE.ActiveCodePane.CodeModule.ReplaceLine startLine, ExpandDim(myLine) 
End Sub 

Trong một mô-đun mã tôi đã:

Sub test() 
    DimAll a, b, c, d As Integer 
    Debug.Print TypeName(a) 
    Debug.Print TypeName(b) 
    Debug.Print TypeName(c) 
    Debug.Print TypeName(d) 
End Sub 

Đây là phần kỳ lạ. Khi tôi làm nổi bật dòng mà bắt đầu DimAll một, và gọi tôi ngượng nghịu tên tiểu DimAll, trong cửa sổ ngay lập tức tôi thấy

được như mong đợi, nhưng trong mô-đun mã tự dòng được thay đổi để

Dim a, b, c, d As Integer 

DimAll đã được thay thế bằng Dim - nhưng phần còn lại của dòng chưa được sửa đổi. Tôi nghi ngờ rằng các dấu phẩy gây nhầm lẫn cho phương thức ReplaceLine. Bất kỳ ý tưởng nào về cách sửa lỗi này?

Answer 1

Khi tôi chạy với trình gỡ lỗi, myLine thay đổi giá trị giữa hai cuộc gọi. Các DimAll trở thành Dim vào lần thứ hai thông qua.

Điều này là do bạn đang thay thế giá trị codeLine sau khi bạn nhập chính If điều kiện bên trong ExpandDim Function.

Tạo một biến mới trong chức năng đó và bạn nên sử dụng tốt ... hoặc vượt qua nó ByVal và bạn tốt:

Function ExpandDim(ByVal codeLine As String) As String