Delphi - Vẽ văn bản nhiều dòng ở chính giữa của một rect

Question

Trong Delphi tôi muốn vẽ văn bản bên trong một TRect. Tôi hy vọng cho các chức năng sau:

1. Vẽ văn bản làm trung tâm theo chiều dọc trong TRect
2. Vẽ văn bản làm trung tâm theo chiều ngang trong TRect
3. Nếu có không gian cho hơn 1 dòng văn bản (sử dụng TRect của chiều cao), vẽ văn bản nhiều dòng
4. Nếu văn bản không vừa trong TRect (trên một hoặc nhiều dòng) thì hãy thêm dấu chấm lửng vào văn bản.

Tôi có thể thấy hàm Windows.DrawText() gần như bao gồm chức năng này, tuy nhiên khi viết văn bản, đa dòng và theo chiều dọc được loại trừ lẫn nhau.

Tôi đã tự hỏi liệu chức năng này có được tích hợp trong các cửa sổ (2000+) không? Nếu không có cách nào để làm điều này mà không cần viết chức năng của riêng tôi?

Answer 1

Xin lỗi, đây là sự kết hợp của tất cả câu trả lời và nhận xét trước đó. Nhưng có vẻ như OP cần hỗ trợ nhiều hơn.

function DrawTextCentered(Canvas: TCanvas; const R: TRect; S: String): Integer; 
var 
    DrawRect: TRect; 
    DrawFlags: Cardinal; 
    DrawParams: TDrawTextParams; 
begin 
    DrawRect := R; 
    DrawFlags := DT_END_ELLIPSIS or DT_NOPREFIX or DT_WORDBREAK or 
    DT_EDITCONTROL or DT_CENTER; 
    DrawText(Canvas.Handle, PChar(S), -1, DrawRect, DrawFlags or DT_CALCRECT); 
    DrawRect.Right := R.Right; 
    if DrawRect.Bottom < R.Bottom then 
    OffsetRect(DrawRect, 0, (R.Bottom - DrawRect.Bottom) div 2) 
    else 
    DrawRect.Bottom := R.Bottom; 
    ZeroMemory(@DrawParams, SizeOf(DrawParams)); 
    DrawParams.cbSize := SizeOf(DrawParams); 
    DrawTextEx(Canvas.Handle, PChar(S), -1, DrawRect, DrawFlags, @DrawParams); 
    Result := DrawParams.uiLengthDrawn; 
end; 

procedure TForm1.FormPaint(Sender: TObject); 
const 
    S = 'This is a very long text as test case for my paint routine.'; 
var 
    R: TRect; 
begin 
    SetRect(R, 100, 100, 200, 140); 
    Canvas.Rectangle(R); 
    InflateRect(R, -1, -1); 
    Caption := Format('%d characters drawn', [DrawTextCentered(Canvas, R, S)]); 
end; 

Answer 2

Đo văn bản trước tiên bằng cách sử dụng DT_CALCRECT. Vượt qua DT_WORDBREAK để chỉ định gói từ được bật. Điều này sẽ cho phép bạn tìm chiều cao yêu cầu cho văn bản của bạn. Sau đó, bạn có thể, trong mã của bạn, tính toán bù đắp theo chiều dọc cung cấp cho bạn văn bản được căn giữa theo chiều dọc và vẽ đến độ lệch đó.