Perl, chuyển đổi băm thành mảng

Question

Nếu tôi có băm trong Perl chứa ánh xạ nguyên hoàn chỉnh và tuần tự (nghĩa là tất cả các phím từ 0 đến n được ánh xạ tới thứ gì đó, không có khóa nào bên ngoài), có phương tiện chuyển đổi này thành một mảng?

Tôi biết tôi có thể lặp qua các cặp khóa/giá trị và đặt chúng vào một mảng mới, nhưng có điều gì đó cho tôi biết phải có phương tiện tích hợp để thực hiện việc này.

Answer 1

Nếu nguồn dữ liệu ban đầu của bạn là một hash:

# first find the max key value, if you don't already know it: 
use List::Util 'max'; 
my $maxkey = max keys %hash; 

# get all the values, in order 
my @array = @hash{0 .. $maxkey}; 

Hoặc nếu dữ liệu ban đầu của bạn nguồn là một hashref:

my $maxkey = max keys %$hashref; 
my @array = @{$hashref}{0 .. $maxkey}; 

---

này rất dễ dàng để kiểm tra sử dụng ví dụ này:

my %hash; 
@hash{0 .. 9} = ('a' .. 'j'); 

# insert code from above, and then print the result... 
use Data::Dumper; 
print Dumper(\%hash); 
print Dumper(\@array); 

$VAR1 = { 
      '6' => 'g', 
      '3' => 'd', 
      '7' => 'h', 
      '9' => 'j', 
      '2' => 'c', 
      '8' => 'i', 
      '1' => 'b', 
      '4' => 'e', 
      '0' => 'a', 
      '5' => 'f' 
     }; 
$VAR1 = [ 
      'a', 
      'b', 
      'c', 
      'd', 
      'e', 
      'f', 
      'g', 
      'h', 
      'i', 
      'j' 
     ]; 

Answer 2

OK, đây không phải là rất "tích hợp" nhưng hoạt động. Nó cũng là IMHO thích hợp hơn với bất kỳ giải pháp liên quan đến "sắp xếp" vì nó nhanh hơn.

map { $array[$_] = $hash{$_} } keys %hash; # Or use foreach instead of map 

Nếu không, kém hiệu quả:

my @array = map { $hash{$_} } sort { $a<=>$b } keys %hash; 

Answer 3

này sẽ để chìa khóa không quy định tại %hashed_keys như undef:

# if we're being nitpicky about when and how much memory 
# is allocated for the array (for run-time optimization): 
my @keys_arr = (undef) x scalar %hashed_keys; 

@keys_arr[(keys %hashed_keys)] = 
    @hashed_keys{(keys %hashed_keys)}; 

Và, nếu bạn đang sử dụng tài liệu tham khảo:

@{$keys_arr}[(keys %{$hashed_keys})] = 
    @{$hashed_keys}{(keys %{$hashed_keys})}; 

Hoặc, nguy hiểm hơn, vì nó giả định những gì bạn nói là đúng (nó có thể không phải lúc nào cũng đúng & hellip; Chỉ cần sayin '!):

@keys_arr = @hashed_keys{(sort {$a <=> $b} keys %hashed_keys)}; 

Nhưng đây là loại bên cạnh điểm. Nếu chúng được lập chỉ mục số nguyên để bắt đầu, thì tại sao chúng lại trong một băm?

Answer 4

Bạn có thể trích xuất tất cả các giá trị từ một hash với values chức năng:

my @vals = values %hash; 

Nếu bạn muốn họ theo một thứ tự đặc biệt, sau đó bạn có thể đặt các phím theo thứ tự mong muốn và sau đó tham gia một hash slice từ rằng:

my @sorted_vals = @hash{sort { $a <=> $b } keys %hash}; 

Answer 5

Như DVK nói, không có xây dựng vào bằng cách nào, nhưng điều này sẽ làm các trick:

my @array = map {$hash{$_}} sort {$a <=> $b} keys %hash; 

hay này:

my @array; 

keys %hash; 

while (my ($k, $v) = each %hash) { 
    $array[$k] = $v 
} 

benchmark để xem đó là nhanh hơn, tôi đoán sẽ là thứ hai.

Answer 6

Perl không cung cấp tích hợp để giải quyết vấn đề của bạn.

Nếu bạn biết rằng các phím bao gồm một phạm vi cụ thể 0..N, bạn có thể tận dụng thực tế là:

my $n = keys(%hash) - 1; 
my @keys_and_values = map { $_ => $hash{$_} } 0 .. $n; 
my @just_values  = @hash{0 .. $n}; 

Answer 7

Kết hợp FM 's và Ether' câu trả lời s cho phép một để tránh xác định một đại lượng vô hướng khác không cần thiết:

my @array = @hash{ 0 .. $#{[ keys %hash ]} }; 

Điều gọn gàng là không giống như với cách tiếp cận scalar, $# hoạt động ở trên ngay cả trong trường hợp không chắc rằng chỉ mục mặc định của phần tử đầu tiên, $[, khác không.

Tất nhiên, điều đó có nghĩa là viết một cái gì đó ngớ ngẩn làm cho khó hiểu như vậy:

my @array = @hash{ $[ .. $#{[ keys %hash ]} }; # Not recommended 

Nhưng sau đó luôn luôn có cơ hội xa rằng ai đó cần nó ở đâu đó (nhăn) ...

Answer 8

@a = @h{sort { $a <=> $b } keys %h}; 

Answer 9

$Hash_value = 
{ 
'54' => 'abc', 
'55' => 'def', 
'56' => 'test', 
}; 
while (my ($key,$value) = each %{$Hash_value}) 
{ 
print "\n $key > $value"; 
} 

Answer 10

Chúng tôi có thể viết một thời gian như sau:

$j =0; 
while(($a1,$b1)=each(%hash1)){ 
    $arr[$j][0] = $a1; 
    ($arr[$j][1],$arr[$j][2],$arr[$j][3],$arr[$j][4],$arr[$j][5],$arr[$j][6]) = values($b1); 
    $j++; 
} 

$ a1 chứa khóa và $ b1 chứa các giá trị Trong ví dụ trên, tôi có Hash của mảng và mảng chứa 6 phần tử.

Answer 11

Một cách dễ dàng là để làm @array = %hash

Ví dụ,

my %hash = (
    "0" => "zero", 
    "1" => "one", 
    "2" => "two", 
    "3" => "three", 
    "4" => "four", 
    "5" => "five", 
    "6" => "six", 
    "7" => "seven", 
    "8" => "eight", 
    "9" => "nine", 
    "10" => "ten", 
); 

my @array = %hash; 

print "@array"; sẽ cho kết quả sau,

3 ba 9 chín 5 năm 8 Tám 2 hai 4 Bốn 1 một 10 mười 7 bảy 0 không 6 sáu