Có cách nào thành ngữ để kiểm tra sự bình đẳng mảng trong Coffeescript không?

Question

Khái niệm

[1, 2, 3] == [1, 2, 3] 

đánh giá để false trong Coffeescript nhưng là có một, cách thành ngữ súc tích để kiểm tra bình đẳng mảng?

Answer 1

Nếu bạn đang đối phó với mảng các con số, và bạn biết rằng không có null hay giá trị không xác định trong mảng, bạn có thể so sánh chúng như dây đàn:

a = [1, 2, 3] 
b = [1, 2, 3] 

console.log "#{a}" is "#{b}" # true 
console.log '' + a is '' + b # true 

Thông báo, tuy nhiên, điều này sẽ phá vỡ ngay sau khi bạn bắt đầu mảng so sánh những thứ khác mà không phải là con số:

a = [1, 2, 3] 
b = ['1,2', 3] 

console.log "#{a}" is "#{b}" # true 

Nếu bạn muốn có một giải pháp mạnh mẽ hơn, bạn có thể sử dụng Array#every:

arrayEqual = (a, b) -> 
    a.length is b.length and a.every (elem, i) -> elem is b[i] 

console.log arrayEqual [1, 2, 3], [1, 2, 3] # true 
console.log arrayEqual [1, 2, 3], [1, 2, '3'] # false 
console.log arrayEqual [1, 2, 3], ['1,2', 3] # false 

Lưu ý rằng lần đầu tiên so sánh độ dài của mảng sao cho arrayEqual [1], [1, 2, 3] không trả về giá trị đúng.

Answer 2

Nếu bạn không nhớ giới thiệu phụ thuộc Underscore.js, bạn có thể sử dụng một số tiện ích của nó. Nó không phải ồ ạt thanh lịch, nhưng tôi không thể nghĩ ra một cách dễ dàng hơn để làm điều đó với coffeescript đồng bằng:

a = [ 1, 2, 3 ] 
b = [ 1, 2, 3 ] 
equal = a.length == b.length and _.all(_.zip(a, b), ([x,y]) -> x is y) 

Answer 3

Tôi sẽ không xem xét thành ngữ này, nhưng đây sẽ là một cách để làm việc đó mà không cần thêm một thư viện thêm :

a = [1, 2, 3, 4] 
b = [22, 3, 4] 

areEqual = true 
maxIndex = Math.max(a.length, b.length)-1 
for i in [0..maxIndex] 
    testEqual = a[i] is b[i] 
    areEqual = areEqual and testEqual 

console.log areEqual 

Phương pháp tiếp cận rõ ràng hơn sẽ sử dụng chức năng reduce() của JavaScript. Đây là một chút ngắn hơn nhưng tôi không chắc chắn tất cả các trình duyệt hỗ trợ giảm.

a = [1, 3, 4, 5] 
b = [1, 3, 4, 5] 

maxIndex = Math.max(a.length, b.length)-1 
areEqual = true 
[0..maxIndex].reduce (p, c, i, ar) -> areEqual = areEqual and (a[i] is b[i]) 

console.log "areEqual=#{areEqual}" 

Answer 4

Tôi là người hâm mộ lớn của Sugar.js. Nếu bạn tình cờ được sử dụng rằng:

a = [1, 2, 3] 
b = [1, 2, 3] 
Object.equal(a, b) 

Answer 5

Sau đây hoạt động tuyệt vời và không cần phụ thuộc:

arrayEqual = (ar1, ar2) -> 
    JSON.stringify(ar1) is JSON.stringify(ar2) 

Answer 6

Hàm này trả true nếu mảng có cùng chiều dài và tất cả các giá trị với cùng một chỉ số có cùng một giá trị. Nó ném một lỗi nếu một trong hai đối số không phải là một mảng.

isArray = Array.isArray || (subject) -> 
    toString.call(subject) is '[object Array]' 

compareArrays = (a, b) -> 
    unless isArray(a) and isArray b 
     throw new Error '`arraysAreEqual` called with non-array' 

    return false if a.length isnt b.length 

    for valueInA, index in a 
     return false if b[index] isnt valueInA 

    true