Làm thế nào để tạo ra một hậu duệ TStringList với Chủ sở hữu sẽ tự động giải phóng TStringList?

Question

tôi hy vọng sẽ tạo ra một cái gì đó giống như một "TOwnedStringList" (tên lớp là một hư cấu) mà tôi có thể xây dựng như:

sl := TOwnedStringList.Create(Self); 
sl.Sorted := True; 
sl.Duplicates := dupIgnore; 
sl.Add(...); 
// etc... 

đâu Self có thể là một mẫu (ví dụ), do đó chủ đầu tư sẽ tự động miễn phí các StringList. Tôi muốn có thể tránh tự gọi số sl.Free.

Điều này có thể không?

Answer 1

Điều đó sẽ hơi lộn xộn một chút. Bạn sẽ cần phải làm một cái gì đó như thế này.

type 
    TOwnerComponent = class(TComponent) 
    private 
    FOwnedObject: TObject; 
    public 
    constructor Create(Owner: TComponent; OwnedObject: TObject); 
    destructor Destroy; override; 
    end; 

    TOwnedStringList = class(TStringList) 
    private 
    FOwner: TOwnerComponent; 
    public 
    constructor Create(Owner: TComponent); 
    destructor Destroy; override; 
    end; 

{ TOwnerComponent } 

constructor TOwnerComponent.Create(Owner: TComponent; OwnedObject: TObject); 
begin 
    inherited Create(Owner); 
    FOwnedObject := OwnedObject; 
end; 

destructor TOwnerComponent.Destroy; 
begin 
    FOwnedObject.Free; 
    inherited; 
end; 

{ TOwnedStringList } 

constructor TOwnedStringList.Create(Owner: TComponent); 
begin 
    inherited Create; 
    if Assigned(Owner) then 
    FOwner := TOwnerComponent.Create(Owner, Self); 
end; 

destructor TOwnedStringList.Destroy; 
begin 
    if Assigned(FOwner) and not (csDestroying in FOwner.ComponentState) then 
    begin 
    FOwner.FOwnedObject := nil; 
    FOwner.Free; 
    end; 
    inherited; 
end; 

Về cơ bản bạn tạo một thể hiện của TOwnerComponent được sở hữu bởi các Owner mà bạn vượt qua để TOwnedStringList.Create. Khi đó Owner chết, nó phá hủy các TOwnerComponent mà lần lượt phá hủy danh sách chuỗi của bạn.

Mã này có khả năng đàn hồi để rõ ràng Free đang được gọi trong danh sách chuỗi.