Excel VBA - Xóa các hàng trống trong bảng

Question

Tôi đang cố gắng chạy macro chọn các ô trống trong cột bảng và xóa toàn bộ hàng.

Tập lệnh dưới đây thực hiện mọi thứ ngoại trừ phần xóa, nhắc nhở run-time error 1004 - "Delete method of Range class failed".

Bất kỳ ý tưởng nào về cách khắc phục sự cố này? Cảm ơn

Sub test() 
Range("Table1[[New]]").Activate 
Selection.SpecialCells(xlCellTypeBlanks).Select 
Selection.EntireRow.Delete 
End Sub 

Answer 1

Câu hỏi hay! Nếu không có một bảng, .EntireRow.Delete luôn hoạt động, nhưng bên trong một bảng có vẻ như không.

này hoạt động:

Sub Test() 
    Dim Rng As Range 
    On Error Resume Next 
    Set Rng = Range("Table1[[New]]").SpecialCells(xlCellTypeBlanks) 
    On Error Goto 0 
    If Not Rng Is Nothing Then 
    Rng.Delete Shift:=xlUp 
    End If 
End Sub 

Answer 2

Bạn thực sự có thể làm điều đó trong một pass, nhưng cần phải sử dụng đối tượng ListObject và DataBodyRange và ListColumns nó thuộc tính:

Sub ClearBlankCellsInColumnNew() 
Dim rngBlanks As Excel.Range 

With Worksheets("Sheet1").ListObjects("Table1") 
    On Error Resume Next 
    Set rngBlanks = Intersect(.DataBodyRange, .ListColumns("New").Range).SpecialCells(xlCellTypeBlanks) 
    On Error GoTo 0 
    If Not rngBlanks Is Nothing Then 
     rngBlanks.Delete 
    End If 
End With 
End Sub 

Answer 3

Bước 1: Thực hiện một helper trong bảng nơi bạn kiểm tra bất kỳ trường trống nào trong hàng đó. Ví dụ, nếu bạn có 3 cột trong bảng của bạn: A (Giá), B (Số lượng) và C (Chi phí), bạn sẽ thêm cột D thứ tư và đặt tên là "Bất kỳ Khoảng trống" nào? Phương trình sẽ là =IF(OR(ISBLANK([@Price]),ISBLANK([@Quantity]),ISBLANK([@Cost])),"Yes","No")

Điều đó sẽ cho bạn một cột để lọc để xem tất cả các khoảng trống.

Bước 2: Trong VBA sau đó bạn sẽ làm như sau:

Range("MyTableNameHere").AutoFilter Field:=Range("MyTableNameHere[Any Blanks?]").Column, Criteria1:="Yes" 
Application.DisplayAlerts = False 
Range("MyTableNameHere").ListObject.DataBodyRange.SpecialCells(xlCellTypeVisible).Delete 
Application.DisplayAlerts = True 
Range("MyTableNameHere").AutoFilter Field:=Range("MyTableNameHere[Any Blanks?]").Column 

này về cơ bản được lọc để các hàng bạn muốn xóa trong bảng sử dụng cột helper, chọn tất cả các dữ liệu hiển thị trong bảng và tháo bàn. Tôi đã tìm kiếm xung quanh làm thế nào để xóa tất cả các hàng có thể nhìn thấy trong một bảng và tìm thấy điều này và fiddled xung quanh cho đến khi tôi đã tìm ra rằng điều này sẽ làm việc. Lấy nó và kết hợp nó với một cột helper để chọn tất cả các hàng với bất kỳ khoảng trắng nào có vẻ giống như những gì bạn muốn.

Answer 4

Thích ứng với câu trả lời trước:

On Error Resume Next 
Set Rng = ListObjects(1).DataBodyRange.SpecialCells(xlCellTypeBlanks) 
On Error GoTo 0 
If Not Rng Is Nothing Then 
Rng.Delete Shift:=xlUp 
End If