Cách kiểm tra hệ điều hành với tự động

Question

Tôi có một dự án sử dụng automake để tạo configure và tất cả các tệp có liên quan (Tôi đang sử dụng lệnh autoreconf để thực hiện tất cả nội dung này). Vì vậy, tôi đang cố gắng để thiết lập một số tập tin có điều kiện để biên dịch khi dự án được biên dịch cho macOS (OS X), Windows hoặc Linux. Nhưng nó không thành công như sau:

$ autoreconf -i .. 
src/Makefile.am:30: error: LINUX does not appear in AM_CONDITIONAL 
autoreconf: automake failed with exit status: 1 

Và phần có chứa các lỗi trong Makefile.am được như sau:

if OSX 
    butt_SOURCES += CurrentTrackOSX.h CurrentTrackOSX.m 
endif 
if LINUX 
    butt_SOURCES += currentTrack.h currentTrackLinux.cpp 
endif 
if WINDOWS 
    butt_SOURCES += currentTrack.h currentTrack.cpp 
endif 

Câu hỏi của tôi là, làm thế nào tôi có thể kiểm tra nếu hệ điều hành là Linux? Và nếu nó có thể, có cách nào tốt hơn để kiểm tra hệ điều hành trong automake?

Answer 1

Bạn có thể phát hiện nó directly in the Makefile, hoặc xác định các điều kiện trong file nguồn configure (có lẽ configure.ac), kể từ khi bạn đang sử dụng autoreconf:

# AC_CANONICAL_HOST is needed to access the 'host_os' variable  
AC_CANONICAL_HOST 

build_linux=no 
build_windows=no 
build_mac=no 

# Detect the target system 
case "${host_os}" in 
    linux*) 
     build_linux=yes 
     ;; 
    cygwin*|mingw*) 
     build_windows=yes 
     ;; 
    darwin*) 
     build_mac=yes 
     ;; 
    *) 
     AC_MSG_ERROR(["OS $host_os is not supported"]) 
     ;; 
esac 

# Pass the conditionals to automake 
AM_CONDITIONAL([LINUX], [test "$build_linux" = "yes"]) 
AM_CONDITIONAL([WINDOWS], [test "$build_windows" = "yes"]) 
AM_CONDITIONAL([OSX], [test "$build_mac" = "yes"]) 

Lưu ý: host_os đề cập đến hệ thống mục tiêu, vì vậy nếu bạn đang biên dịch chéo nó đặt hệ điều hành có điều kiện của hệ thống bạn đang biên soạn thành.

Answer 2

Bạn đã thử sử dụng lệnh lsb_release để xác định loại và phiên bản hệ điều hành?