Trong Moose, làm thế nào để sửa đổi một thuộc tính bất cứ lúc nào nó được thiết lập?

Question

Nếu bạn có một thuộc tính cần phải sửa đổi bất kỳ lúc nào được thiết lập, có cách nào ngắn gọn để viết ngắn dòng này và tự động mút trực tiếp với nội dung của $self, như được làm trong ví dụ này?

package Foo; 
use Moose; 

has 'bar' => (
    isa => 'Str', 
    reader => 'get_bar', 
); 

sub set_bar { 
    my ($self, $bar) = @_; 
    $self->{bar} = "modified: $bar"; 
} 

Tôi xem là trigger, nhưng dường như yêu cầu cùng một cách tiếp cận.

Đang làm việc trực tiếp với tham chiếu băm trong $self được coi là thực hành không tốt trong Moose hoặc tôi lo lắng về sự cố không?

Answer 1

Tôi không chắc chắn những loại thay đổi bạn cần, nhưng bạn có thể có thể đạt được những gì bạn cần bằng cách sử dụng loại cưỡng chế:

package Foo; 
use Moose; 

use Moose::Util::TypeConstraints; 

subtype 'ModStr' 
    => as 'Str' 
    => where { /^modified: /}; 

coerce 'ModStr' 
    => from 'Str' 
    => via { "modified: $_" }; 

has 'bar' => ( 
    isa => 'ModStr', 
    is => 'rw', 
    coerce => 1, 
); 

Nếu bạn sử dụng cách tiếp cận này, không phải tất cả giá trị đều sẽ được sửa đổi. Bất kỳ điều gì vượt qua xác thực là ModStr sẽ được sử dụng trực tiếp:

my $f = Foo->new(); 
$f->bar('modified: bar'); # Set without modification 

Điểm yếu này có thể được chấp nhận hoặc có thể làm cho phương pháp này không thể sử dụng được. Trong hoàn cảnh thích hợp, nó thậm chí có thể là một lợi thế.

Answer 2

Tôi nghĩ rằng bằng cách sử dụng tài liệu tham khảo băm là tốt trong một trigger như thế này:

package Foo; 
use Moose; 

has 'bar' => ( 
    isa => 'Str', 
    is => 'rw', 
    trigger => sub { $_[0]->{bar} = "modified: $_[1]" }, 
); 

Các kích hoạt cũng bắn khi thanh arg thông qua với các nhà xây dựng. Điều này sẽ không xảy ra nếu bạn định nghĩa phương thức set_bar của riêng mình hoặc với một công cụ sửa đổi phương thức.

lại: tham chiếu băm - Nói chung, tôi nghĩ tốt nhất nên gắn với trình định vị thuộc tính/getters trừ khi (như với trình kích hoạt ở trên) không có cách thay thế dễ dàng.

BTW bạn có thể tìm thấy điều này recent post about triggers bởi nothingmuch thú vị.

Answer 3

Nếu giao dịch trực tiếp với hàm băm khiến bạn lo ngại, bạn có thể chỉ định một nhà văn thay thế và sau đó sử dụng nó từ bên trong một nhà văn 'công khai' được đặt tên thích hợp.

package Foo; 
use Moose; 

has 'bar' => (
    isa => 'Str', 
    reader => 'get_bar', 
    writer => '_set_bar', 
); 

sub set_bar { 
    my $self = shift; 
    my @args = @_; 
    # play with args; 
    return $self->_set_bar(@args); 
} 

Điều này, hoặc trình kích hoạt, sẽ đánh tôi như một cách tiếp cận tốt tùy thuộc vào thời điểm và cách thức bạn cần thao tác đối số.

(từ chối trách nhiệm: Mã chưa được kiểm tra bằng văn bản từ bộ nhớ, duyệt SO trên một netbook với truy cập cạnh ổn định?)

Answer 4

Bạn có thể sử dụng công cụ sửa đổi phương thức 'xung quanh'. Một cái gì đó như thế này:

has 'bar' => (
    isa => 'Str', 
    reader => 'get_bar', 
    writer => 'set_bar' 
); 

around 'set_bar' => sub { 
    my ($next, $self, $bar) = @_; 
    $self->$next("Modified: $bar"); 
}; 

Và có, làm việc trực tiếp với giá trị băm được coi là hành vi xấu.

Ngoài ra, vui lòng không giả định rằng tùy chọn tôi đã trình bày nhất thiết phải là tùy chọn phù hợp. Việc sử dụng các kiểu con và ép buộc sẽ là giải pháp phù hợp nhất - nếu bạn nghĩ về tham số của mình dưới dạng một loại có thể được sử dụng lại trong toàn bộ ứng dụng của bạn sẽ dẫn đến thiết kế tốt hơn nhiều. thực hiện bằng cách sử dụng 'xung quanh'. Xem câu trả lời từ @daotoad.