Delphi dbgrid liên tục cuộn

Question

Tôi đang tạo một ứng dụng chứa đơn đặt hàng và in hóa đơn. Tôi có một số nhãn, tedits, tmemos, các nút, một nguồn dữ liệu, một adotable, một popupmenu, và một dbgrid trên form của tôi.

Khi tôi tạo chương trình và cuộn xuống thanh cuộn dbgrid, nó cuộn sau khi tôi nhả chuột. Nhưng tôi muốn cuộn liên tục.

Chúc mừng

Answer 1

Đó được gọi là theo dõi ngón tay cái. Tạo ra một lớp mới để ghi đè hành vi cuộn. Ví dụ về cách sử dụng một lớp interposer:

type 
    TDBGrid = class(DBGrids.TDBGrid) 
    private 
    procedure WmVScroll(var Message: TWMVScroll); message WM_VSCROLL; 
    end; 

    TForm1 = class(TForm) 
    DBGrid1: TDBGrid; 
    .. 

implementation 

procedure TDBGrid.WmVScroll(var Message: TWMVScroll); 
begin 
    if Message.ScrollCode = SB_THUMBTRACK then 
    Message.ScrollCode := SB_THUMBPOSITION; 
    inherited; 
end; 

Bạn cũng có thể thay thế các WindowProc của sự kiểm soát nếu bạn không muốn lấy được một lớp mới. Tất cả những gì bạn cần làm là xử lý thông báo WM_VSCROLL. Here là một ví dụ về cách thực hiện điều đó.

Answer 2

Dưới đây là giải pháp khác Sertac Akyuz đề cập mà không cần phải lấy được một lớp mới từ TDBGrid:

private 
    FOrgDBGridWndProc: TWndMethod; 
    procedure DBGridWndProc(var Msg: TMessage); 
    // ... 
    end; 

procedure TForm1.FormCreate(Sender: TObject); 
begin 
    FOrgDBGridWndProc:= DBGrid1.WindowProc; 
    DBGrid1.WindowProc := DBGridWndProc; 
end; 

procedure TForm1.DBGridWndProc(var Msg: TMessage); 
begin 
    if (Msg.Msg = WM_VSCROLL) and 
    (LongRec(Msg.wParam).Lo = SB_THUMBTRACK) then 
    begin 
     LongRec(Msg.wParam).Lo := SB_THUMBPOSITION; 
    end; 
    if Assigned(FOrgDBGridWndProc) then 
    FOrgDBGridWndProc(Msg); 
end;