chèn đầy đủ ADO Recordset vào bảng ACCESS hiện tại KHÔNG CÓ LOOP

Question

Tôi có một bản ghi ADO đầy trong mô-đun VBA của tôi. Tôi cũng có một bảng trong ACCESS có cấu trúc chính xác giống như recordset.

Bây giờ tôi điền vào bảng bằng cách sử dụng một vòng lặp (mà là tốt) đi qua mỗi bản ghi số liệu.

Điều tôi thắc mắc: có cách nào để chèn toàn bộ bản ghi vào bảng truy cập không? (và quan trọng hơn: điều này sẽ nhanh hơn đáng kể)

Answer 1

Dưới đây là một ví dụ cơ bản (chạy từ excel trong trường hợp này) minh họa bằng cách sử dụng một recordset bị ngắt kết nối để thêm bản ghi.

Sub Tester() 

    Dim con As ADODB.Connection, rs As ADODB.Recordset 
    Dim i As Long 

    Set con = getConn() 

    Set rs = New ADODB.Recordset 
    rs.CursorLocation = adUseClient '<<<< important! 

    'get an empty recordset to add new records to 
    rs.Open "select * from Table1 where false", con, _ 
      adOpenDynamic, adLockBatchOptimistic 

    'disconnect the recordset and close the connection 
    Set rs.ActiveConnection = Nothing 
    con.Close 
    Set con = Nothing 

    'add some new records to our test recordset 
    For i = 1 To 100 
     rs.AddNew 
     rs("UserName") = "Newuser_" & i 
    Next i 

    'reconnect to update 
    Set con = getConn() 
    Set rs.ActiveConnection = con 

    rs.UpdateBatch '<<< transfer to DB happens here: no loop! 

    rs.Close 

    'requery to demonstrate insert was successful 
    rs.Open "select * from Table1", con, _ 
      adOpenDynamic, adLockBatchOptimistic 

    Do While Not rs.EOF 
     Debug.Print rs("ID").Value, rs("UserName").Value 
     rs.MoveNext 
    Loop 

    rs.Close 
    con.Close 
End Sub 

Function getConn() As ADODB.Connection 
    Dim rv As New ADODB.Connection 
    Dim strConn As String 

    strConn = "Provider=Microsoft.ACE.OLEDB.12.0;" _ 
    & "Data Source = " & ThisWorkbook.Path & "\Test.accdb" 

    rv.Open strConn 
    Set getConn = rv 
End Function 

Answer 2

Không. Không có tương đương ngược - có thể là SetRows - với phương thức GetRows.

Answer 3

VBA Recordsets tồn tại hầu như trong ký ức gọi trong thời gian chạy cho đến khi họ được chứa vào một định dạng vật lý thực tế (ví dụ, csv, txt, xlsx, xml, cơ sở dữ liệu tạm thời bảng) lưu vào đĩa cứng. Điều này tương tự như các khung dữ liệu trong R hoặc Python pandas, SAS datasets, mảng PHP và các cấu trúc dữ liệu khác.

Xem xét xuất ADO của bạn ở định dạng như vậy bằng cách sử dụng các phương pháp CopyFromRecordset vào bảng tính Excel để lưu dưới dạng csv, txt, xlsx hoặc xml. Ngoài ra, bạn có thể sử dụng phương thức Save để lưu bản ghi trong loại định dạng liên tục như xml.

Sau đó, thêm tập tin kết quả để MS Access bảng với các tính năng di chuyển dữ liệu tự động của nó:

• Đối với bảng tính: DoCmd.TransferSpreadsheet
• Đối txt, csv, hoặc các tập tin khác được phân định: DoCmd.TransferText
• Đối với file xml : Application.ImportXML
• Đối với bảng cơ sở dữ liệu được liên kết hoặc ODBC/OLEDB được liên kết: INSERT INTO nối truy vấn SQL

---