Thay đổi kích thước khung hình xung quanh một bitmap?

Question

Hãy hình dưới đây tôi sẽ sử dụng cho các ví dụ sau:

Kích thước unchaged hiện đang 96 x 71

phép nói rằng tôi muốn thay đổi kích thước canvas để 115 x 80 - hình ảnh kết quả nên sau đó là:

Cuối cùng nếu tôi thay đổi kích cỡ nó đến một kích thước nhỏ hơn so với vải ban đầu là, ví dụ như 45 x 45 đầu ra sẽ xuất hiện như sau:

Đây là những gì tôi đã cố gắng cho đến nay:

procedure ResizeBitmapCanvas(Bitmap: TBitmap; H, W: Integer); 
var 
    Bmp: TBitmap; 
    Source, Dest: TRect; 
begin 
    Bmp := TBitmap.Create; 
    try 
    Source := Rect(0, 0, Bitmap.Width, Bitmap.Height); 
    Dest := Source; 
    Dest.Offset(Bitmap.Width div 2, Bitmap.Height div 2); 
    Bitmap.SetSize(W, H); 
    Bmp.Assign(Bitmap); 
    Bmp.Canvas.FillRect(Source); 
    Bmp.Canvas.CopyRect(Dest, Bitmap.Canvas, Source); 
    Bitmap.Assign(Bmp); 
    finally 
    Bmp.Free; 
    end; 
end; 

procedure TForm1.Button1Click(Sender: TObject); 
begin 
    ResizeBitmapCanvas(Image1.Picture.Bitmap, 110, 110); 
end; 

Nếu bạn thử ở trên trên một bitmap được tải vào một TImage thì bitmap thực tế không ở giữa, canvas sẽ thay đổi kích thước.

Các thuộc tính tôi đã đặt ra cho hình ảnh là:

Image1.AutoSize := True; 
Image1.Center := True; 
Image1.Stretch := False; 

Tôi nghĩ rằng nó có thể là dòng Dest.Offset(Bitmap.Width div 2, Bitmap.Height div 2); mà cần nhìn vào, để tính toán vị trí trung tâm có đúng không?

Mã đã được điều chỉnh/sửa đổi đôi chút từ câu hỏi gần đây David Heffernan trả lời.

Làm cách nào để thay đổi kích thước khung hình bao quanh bitmap, nhưng không kéo giãn bitmap?

Answer 1

Tôi nghĩ rằng đây là những gì bạn đang tìm kiếm:

procedure ResizeBitmapCanvas(Bitmap: TBitmap; H, W: Integer; BackColor: TColor); 
var 
    Bmp: TBitmap; 
    Source, Dest: TRect; 
    Xshift, Yshift: Integer; 
begin 
    Xshift := (Bitmap.Width-W) div 2; 
    Yshift := (Bitmap.Height-H) div 2; 

    Source.Left := Max(0, Xshift); 
    Source.Top := Max(0, Yshift); 
    Source.Width := Min(W, Bitmap.Width); 
    Source.Height := Min(H, Bitmap.Height); 

    Dest.Left := Max(0, -Xshift); 
    Dest.Top := Max(0, -Yshift); 
    Dest.Width := Source.Width; 
    Dest.Height := Source.Height; 

    Bmp := TBitmap.Create; 
    try 
    Bmp.SetSize(W, H); 
    Bmp.Canvas.Brush.Style := bsSolid; 
    Bmp.Canvas.Brush.Color := BackColor; 
    Bmp.Canvas.FillRect(Rect(0, 0, W, H)); 
    Bmp.Canvas.CopyRect(Dest, Bitmap.Canvas, Source); 
    Bitmap.Assign(Bmp); 
    finally 
    Bmp.Free; 
    end; 
end; 

Tôi không thể nhớ nếu XE hỗ trợ thiết Width và Height cho một TRect. Nếu không, hãy thay đổi mã thành

Source.Right := Source.Left + Min(W, Bitmap.Width); 

v.v.