Cách thích hợp để kiểm tra xem Excel OLE có khả dụng không?

Question

Tôi cần kiểm tra xem tôi có thể sử dụng Excel OLE từ chương trình của mình vì nó có thể được khởi chạy trên PC không có Excel hay không. Mã mẫu trên mạng giả định Excel được cài đặt, nhưng nếu không thì sao?

XLApp := CreateOleObject('Excel.Application'); 
try 
    // Hide Excel 
    XLApp.Visible := False; 
    // Open the Workbook 
    XLApp.Workbooks.Open(aPath); 
    ...snip... 
finally 
    // Quit Excel 
    if not VarIsEmpty(XLApp) then 
    begin 
    XLApp.Quit; 
    XLAPP := Unassigned; 
    end; 
end; 

Đó có phải là mã đúng để tìm hiểu xem Excel có được cài đặt không?

//Try to create Excel OLE 
try 
    XLApp := CreateOleObject('Excel.Application'); 
except 
    ShowMessage('Error opening Excel'); 
    Exit; 
end; 

Answer 1

Bạn có thể sử dụng mã dựa trên Scalabium's tip để kiểm tra xem Excel có khả dụng hay không. Hoặc một cái gì đó như:

uses ComObj, ActiveX; 

function IsObjectAvailable(const ClassName: string): Boolean; 
var 
    ClassID: TCLSID; 
begin 
    Result := Succeeded(CLSIDFromProgID(PWideChar(WideString(ClassName)), 
    ClassID)); 
end; 

Bạn cũng có thể kiểm tra xem Excel đang chạy bằng cách sử dụng đoạn mã sau:

function IsObjectActive(const ClassName: string): Boolean; 
var 
    ClassID: TCLSID; 
    Unknown: IUnknown; 
begin 
    Result := False; 
    if Succeeded(CLSIDFromProgID(PWideChar(WideString(ClassName)), ClassID)) then 
    Result := Succeeded(GetActiveObject(ClassID, nil, Unknown)); 
end; 

Và rồi trong một số thủ tục hoặc sự kiện:

procedure TForm1.Button1Click(Sender: TObject); 
begin 
    if IsObjectAvailable('Excel.Application') then 
    ShowMessage('Excel is available'); 
    if IsObjectActive('Excel.Application') then 
    ShowMessage('Excel is running'); 
end;